Функция события Flash AS3 с аргументами

Question

Мне нужно создать функцию события, в которой есть параметры, которые вы передадите, что будет выглядеть примерно так.

public function foo(e:Event, args) 
    { 
     trace(args[0]); 
    } 


    addEventListener("fooEvent", foo); 
    dispatchEvent(new Event("fooEvent", true), args); 

В любом случае, что я мог бы сделать это? Спасибо, парни.

Answer 1

Попробуйте это:

package { 
    import flash.events.Event; 

    public class CustomEvent extends Event { 
    public var params:Object; 

    public function CustomEvent(type:String, paramsObj:Object = null, bubbles:Boolean = true, cancelable:Boolean = true) { 
     super(type, bubbles, cancelable); 

     if (paramsObj) { 
     params = paramsObj; 
     } 
    } 

    public override function clone():Event{ 
     return new CustomEvent(type, params, bubbles, cancelable); 
    } 

    public override function toString():String{ 
     return formatToString("CustomEvent", "params", "type", "bubbles", "cancelable"); 
    } 
    } 
} 

Вы можете структурировать событие, как:

dispatchEvent(new CustomEvent("fooEvent", {param1:"foo", param2:"bar"})) 

и извлекать данные, такие как:

addEventListener("fooEvent", function(event:CustomEvent):void { 
    trace("param1: " + event.params.param1); 
    trace("param2: " + event.params.param2); 
});