Как отправить объект формы из Excel в тело электронной почты?

Question

Я борюсь с этим (казалось бы) простым шагом в макросе, который я пытаюсь написать. У меня есть объект формы Excel, который я пытаюсь скопировать, затем вставьте в элемент почты Outlook. Объект shape на самом деле является продуктом «инструмента для камеры» Excel. То, что я сделал, было создано диаграммой, которую мне нужно перевернуть на 90 градусов для просмотра. Инструмент камеры делает это простым. Единственная проблема, с которой я столкнулся, - это вставить эту фигуру в объект перспективы. Предложения?

Вот мой код до сих пор:

Sub emailer() 

Dim wb As Workbook 
Dim ws As Worksheet 
Dim p As Shape 
Dim o As Outlook.Application 
Dim om As Outlook.MailItem 
Dim rec As Outlook.Recipient 
Dim recs As Outlook.Recipients 

'create the outlook session 
Set o = CreateObject("Outlook.Application") 
'create the message 
Set om = o.CreateItem(olMailItem) 
Set recs = om.Recipients 
Set rec = recs.Add("email@email.com") 
rec.Type = 1 

Set wb = ActiveWorkbook 
Set ws = ActiveWorkbook.Worksheets("Chart_Pic") 

Set p = ws.Shapes("Picture 2") 
p.CopyPicture 


With om 
.SentOnBehalfOfName = "email@email.com" 
.Subject = "Subject" 
.HTMLBody = "This is a test" & vbCrLf & vbCrLf & [where I want the shape to go] 


For Each rec In om.Recipients 
rec.Resolve 
Next 

om.Send 

End With 

Set o = Nothing 

Answer 1

Вы можете использовать буфер обмена для копирования/вставки изображения. Но для этого вам нужен редактор почты Outlook, который может работать с буфером обмена. Например, WordEditor.

Пример:

Sub emailer() 

Set oOlApp = CreateObject("Outlook.Application") 

Set oOlMItem = oOlApp.CreateItem(olMailItem) 

Set oWB = ActiveWorkbook 
Set oWS = ActiveWorkbook.Worksheets("Chart_Pic") 

Set oPic = oWS.Shapes("Picture 2") 
oPic.CopyPicture ' oPic is now in Clipboard 


With oOlMItem 

    .Display 

    .To = "email@email.com" 
    .Subject = "Subject" 

    Set oOlInsp = .GetInspector 
    Set oWdDoc = oOlInsp.WordEditor ' get Word Document from the MailBody 

    Set oWdContent = oWdDoc.Content 
    oWdContent.InsertParagraphBefore 
    Set oWdRng = oWdDoc.Paragraphs(1).Range 
    oWdRng.InsertBefore "This is a test" 
    oWdRng.InsertParagraphAfter 
    oWdRng.InsertParagraphAfter 

    Set oWdRng = oWdDoc.Paragraphs(3).Range 
    oWdRng.Paste ' paste from oPic Clipboard 

    olFormatHTML = 2 
    .BodyFormat = olFormatHTML ' change to HTML 


End With 

End Sub