Как получить статус выхода команды в конвейере getline?

Question

В POSIX awk, как мне получить статус выхода (код возврата) от commandпосле обработки его вывода через command | getline var? Я хочу, чтобы мой awk-скрипт был exit 1, если command вышел с ненулевым статусом выхода.

Например, предположим, что у меня был сценарий AWK именем foo.awk который выглядит следующим образом:

function close_and_get_exit_status(cmd) { 
    # magic goes here... 
} 
BEGIN { 
    cmd = "echo foo; echo bar; echo baz; false" 
    while ((cmd | getline line) > 0) 
     print "got a line of text: " line 
    if (close_and_get_exit_status(cmd) != 0) { 
     print "ERROR: command '" cmd "' failed" | "cat >&2" 
     exit 1 
    } 
    print "command '" cmd "' was successful" 
} 

я хочу следующее случиться:

$ awk -f foo.awk 
got a line of text: foo 
got a line of text: bar 
got a line of text: baz 
ERROR: command 'echo foo; echo bar; echo baz; false' failed 
$ echo $? 
1 

Согласно POSIX specification for awk, command | getline возвращает 1 для успешного ввода, ноль для конца файла и -1 для ошибки. Это не ошибка, если command выходит с ненулевым статусом выхода, поэтому это невозможно использовать, чтобы проверить, выполнено ли command и не удалось.

Аналогично, close() не может использоваться для этой цели: close() возвращает ненулевое значение, только если сбой завершен, а не если соответствующая команда возвращает ненулевой статус выхода. (В простаке, close(command) возвращает статус выхода command. Это поведение, я хотел бы, но я думаю, что это нарушает спецификацию POSIX и не все реализации AWK ведут себя таким образом.)

Функция AWK system() возвращает статус выхода команды, но насколько я могу судить, нет способа использовать getline.

Answer 1

Самого простое, что нужно сделать, это просто эхо статуса выхода из оболочки после выполнения команды, а затем прочитал, что с GetLine. например

$ cat tst.awk  
BEGIN { 
    cmd = "echo foo; echo bar; echo baz; false" 

    mod = cmd "; echo \"$?\"" 
    while ((mod | getline line) > 0) { 
     if (numLines++) 
      print "got a line of text: " prev 
     prev = line 
    } 
    status = line 
    close(mod) 

    if (status != 0) { 
     print "ERROR: command '" cmd "' failed" | "cat >&2" 
     exit 1 
    } 
    print "command '" cmd "' was successful" 
} 

$ awk -f tst.awk 
got a line of text: foo 
got a line of text: bar 
got a line of text: baz 
ERROR: command 'echo foo; echo bar; echo baz; false' failed 
$ echo $? 
1 

В случае, если кто-то читает это и рассматривает возможность использования GetLine, убедитесь, что вы читали http://awk.freeshell.org/AllAboutGetline и полностью понять все предостережения и последствия делать это первым.

Answer 2

Не идеальное решение, но вы можете сделать:

"command || echo failure" | getline var; ... if(var == "failure") exit; 

Существует некоторая неопределенность в том, что вы должны выбрать строку «провал» таким образом, чтобы повелевать никогда не может генерировать ту же строку, но возможно, это адекватное обходное решение.

Answer 3

Ниже ужасающе сложно, но:

• является POSIX совместимым (в основном - fflush() еще не в стандарте POSIX, but it will be и это широко распространено)
• общее (работает независимо от того, какой выход выдает команда)
• не вводит никакой задержки обработки. Принятый ответ на этот вопрос делает линию доступной только после того, как команда следующая строка. Если команда медленно выводит строки и быстро реагирует (например, случайные события, напечатанные системой IDS, которая должна инициировать изменение брандмауэра или уведомление по электронной почте), этот ответ может быть более уместным, чем принятый ответ.

Основной подход состоит в том, чтобы эхоиздать статус выхода/возвращаемое значение после завершения команды. Если эта последняя строка не равна нулю, выйдите из awk-скрипта с ошибкой. Чтобы код не ошибался в строке вывода текста командой для статуса выхода, каждая строка текста, выводимая командой, добавляется буквой, которая позже удаляется.

function stderr(msg) { print msg | "cat >&2"; } 
function error(msg) { stderr("ERROR: " msg); } 
function fatal(msg) { error(msg); exit 1; } 

# Wrap cmd so that each output line of cmd is prefixed with "d". 
# After cmd is done, an additional line of the format "r<ret>" is 
# printed where "<ret>" is the integer return code/exit status of the 
# command. 
function safe_cmd_getline_wrap(cmd) { 
    return             \ 
     "exec 3>&1;"          \ 
     "ret=$("           \ 
     " exec 4>&1;"         \ 
     " { ("cmd") 4>&-; echo $? >&4; } 3>&- |"  \ 
     " awk '{print\"d\"$0;fflush()}' >&3 4>&-;"  \ 
     ");"            \ 
     "exec 3>&-;"          \ 
     "echo r${ret};" 
} 

# like "cmd | getline line" except: 
# * if getline fails, the awk script exits with an error 
# * if cmd fails (returns non-zero), the awk script exits with an 
#  error 
# * safe_cmd_getline_close(cmd) must be used instead of close(cmd) 
function safe_cmd_getline(cmd,  wrapped_cmd,ret,type) { 
    wrapped_cmd = safe_cmd_getline_wrap(cmd) 
    ret = (wrapped_cmd | getline line) 
    if (ret == -1) fatal("failed to read line from command: " cmd) 
    if (ret == 0) return 0 
    type = substr(line, 1, 1) 
    line = substr(line, 2) 
    if (type == "d") return 1 
    if (line != "0") fatal("command '" cmd "' failed") 
    return 0 
} 
function safe_cmd_getline_close(cmd) { 
    if (close(safe_cmd_getline_wrap(cmd))) fatal("failed to close " cmd) 
} 

используется выше, как это:

cmd = "ls no-such-file" 
while (safe_cmd_getline(cmd)) { 
    print "got a line of text: " line 
} 
safe_cmd_getline_close(cmd)