Ошибка в наборе данных firstobs

Question

Я очень, очень новичок в SAS и читал вопросы о стеке и документации SAS, чтобы написать код для очень конкретной цели. Мне было трудно достичь моей цели и понять SAS по двум причинам: я могу выполнять код только на удаленном сервере, хотя SSH, потому что у меня нет SAS локально (поэтому при каждом изменении мне нужно загрузить файл, выполнить и верните файлы журнала и lst, проверьте наличие ошибок), и большинство вводных тем, которые я прочитал, не сразу применимы к моей задаче (меня интересует только использование SAS для автоматизации определенной процедуры извлечения данных).

Моя цель состоит в том, чтобы:

• чтения определенных линеечки (т.е. идентификатор для запаса) на файл CSV;
• цикл каждого тикера, получая необходимую информацию через определенные макросы.

До сих пор мне удалось прочитать CSV и импортировать эти данные в набор данных. Чтобы проверить, правильно ли работают основы того, что мне нужно, я сделал следующий код. Моя цель состояла в цикле, чтобы присвоить тикер определенной «переменной» currentticker (возможно, не правильному имени для нее) и распечатать ее. В файле csv есть только две строки: «Первая» и «DELL» - в другой.

libname mydir '~/'; 

data companies; 
    infile 'sastests/data/tickers.csv' delimiter=','; 
    input ticker $; 
run; 

proc sql; 
select count(*) 
into  :OBSCOUNT 
from  companies; 
quit; 

proc print data=companies; 
    var ticker; 
run; 

%do iter = 1 to &OBSCOUNT; 
    data currentticker; 
    set companies (firstobs = iter obs = iter); 
    run; 
    proc print data = currentticker; 
    run; 
%end; 

Когда я просматриваю файл журнала, я сразу же получаю сообщение об ошибке в опции firstobs набора данных.

Invalid value for the FIRSTOBS option. 

Почему это так? Не должно ли оно быть числом, таким образом, действующим как FIRSTOBS?

Благодарим вас за это заранее.

Редактировать 1: Заголовок не было хорошим описанием проблемы.

Редактировать 2: Примеры макросов, которые будут использоваться для одного тикера. Поиск должен быть отправлен с кодом &. lookup будет вызываться, затем getopt и, наконец, export_tab. Этот код не относится к моему авторству, я немного изменил его после того, как он был представлен в качестве образца кода WRDS.

%macro lookup; 

    data idcodes (keep=secid); 
    set optionm.secnmd; 
    where lowcase(ticker) = &ticker; 

    proc sort data=idcodes nodupkey; 
    by secid; 

    proc print data=idcodes; 

%mend; 

%macro getopt(year); 

    proc sql; 
    create table temp as 
     select a.* 
     from 
     optionm.vsurfd&year as a, 
     idcodes as b 
     where 
     a.secid = b.secid; 
    run; 

    proc datasets; 
    append base=work.&outputfile 
    data=work.temp; 
    run; 

%mend; 

%macro export_tab; 

    proc export data=&outputfile outfile="&outputfile._out.txt" dbms=tab replace; 
    run; 

%mend; 

Answer 1

Это в основном другой ответ, поэтому поставим его здесь. Вот как я подходил к второй части - никаких макросов вообще. Я предполагаю, что их ежегодные наборы данных отсортированы уже сексидом; если нет, это может быть немного сложнее, просто чтобы избежать слияния.

proc sql; 
select quote(ticker) into :tickerlist separated by ',' from companies; 
quit; 

data idcodes; *you could also create this by merging optiomn.secnmd to companies by ticker.; 
set optionm.secnmd; 
where lowcase(ticker) in (&tickers.); 
run; 

proc sort data=idcodes nodupkey; 
by secid; 
run; 

proc print data=idcodes; 
run; 

data lotsofyears/view=lotsofyears; 
set 
optionm.vsurfd2010 
optionm.vsurfd2011 
optionm.vsurfd2012 
optionm.vsurfd2013 
; *or however many you need, you could generate this list if it is long; 
by secid; 
run; 

data mydata; 
merge lotsofyears(in=a) idcodes(in=b); 
by secid; 
filenm=cats("c:\mydir\mydata_",ticker,".dat"); *or secid if that is better; 
run; 
proc sort data=mydata; 
by ticker; 
run; 
data _null_; 
set mydata; 
file a filevar=filenm dlm='09'x lrecl=32767; 
put (_all_)($); *or perhaps a more complex put statement - see what proc export generates; 
run; 

Answer 2

Вы должны предшествовать макропеременную по &, так firstobs=&iter..

Однако я не уверен, что вы действительно хотите это сделать. Почти все, что вы, возможно, захотите сделать, макро-итерацией по набору данных, которую вы можете сделать, путем регулярного повтора по набору данных и, возможно, с использованием групп BY. Макро итерация очень неэффективна по сравнению с использованием встроенных методов SAS.

Чтобы вызвать набор кодов для каждой строки в наборе данных, вы должны сделать что-то вроде этого.

%macro pulldata(ticker); 
data stock_data; 
set big_database; 
where ticker="&ticker"; 
file "c:\mydir\myfile_&ticker..csv" dlm=',' lrecl=32767; *double period - first is macro variable delimiter; 
put (_all_) ($); 
run; 
%mend pulldata; 

data _null_; 
set companies; 
call execute('%pulldata(',ticker,')'); 
run; 

Вы также можете сделать что-то вроде этого, где мы используем опцию filevar, чтобы позволить набор данных высовываться в несколько файлов (должны быть отсортированы по filevar!)

proc sql; 
select quote(ticker) into :tickerlist separated by ',' from companies; 
quit; 

data mydata; 
set bigdata; 
where ticker in (&tickerlist.); 
filen = cats('c:\mydata\myfile_',ticker,'.csv'); 
run; 

proc sort data=mydata; 
by filen; 
run; 

data _null_; 
set mydata; 
file a filevar=filen dlm=',' lrecl=32767; 
put (_all_) ($); 
run;