Открытие соединения ADODB из Excel - Ошибка 424

Question

Я пытаюсь создать универсальную функцию для возврата открытого соединения. Однако код ошибки вызывается в последней строке, когда я устанавливаю функцию в объект соединения. Нужны некоторые направления, чтобы добиться этого. Спасибо!

'' 
' Function to open an ADODB connection and return the connection object 
' @param strDBPath string containing full path to database of interest 
' @param strUserID optional string containing user name to use when establishing the connection (default: vbNullString) 
' @param strPassword optional string containing password to use when establishing the connection (default: vbNullString) 
' @param intOptionsEnum optional integer to open the connection synchronously (-1) (defualt) - 16 to open connection asynchronously 
' @return Object containing opened ADODB connection 
' @remarks Have only tested this on .mdb database (not .accdb) 
Public Function vfnc_StartConnection(_ 
    strDBPath As String, _ 
    Optional strUserID As String = vbNullString, _ 
    Optional strPassword As String = vbNullString, _ 
    Optional intOptionsEnum As Integer = -1 _ 
    ) As Object 

    Dim objConn As Object: Set objConn = CreateObject("ADODB.connection") 
    Dim strDataSource As String: strDataSource = "Data Source=" & strDBPath & ";" 
    '#If VB7 And Win64 Then 
     strProvider = "Provider=Microsoft.ACE.OLEDB.12.0; " 
    '#Else 
     'strProvider = "Provider=Microsoft.Jet.OLEDB.4.0; " 
    '#End If 
    Set vfnc_StartConnection = objConn.Open(strProvider & strDataSource, strUserID, strPassword, intOptionsEnum) 'Error occurs here 
End Function 

Answer 1

Открытый метод объекта Connection не возвращает объект. Поэтому не стоит устанавливать что-то objConn.Open.

Вы, вероятно, просто хочу, чтобы вернуть себе открытый объект objConn, т.е.

'Open the connection 
    objConn.Open strProvider & strDataSource, strUserID, strPassword, intOptionsEnum 

    'Now that the connection has been opened, return the connection to the calling routine 
    Set vfnc_StartConnection = objConn 

Answer 2

Вот мое взятие на этом, используя ConnectionString properity, частично основываясь на ответе на YowE3K.

Public Function vfnc_StartConnection(strDBPath As String, Optional strUserID As String = "admin", Optional strPassword As String = vbNullString, Optional intOptionsEnum As Integer = -1) As ADODB.Connection 

    Dim objConn As ADODB.Connection 
    Set objConn = New ADODB.Connection 

    Dim strDataSource As String 
    Dim strprovider As String 
    strDataSource = "Data Source=" & strDBPath & ";" 
    strprovider = "Provider=Microsoft.ACE.OLEDB.12.0; " 

    objConn.ConnectionString = strprovider & strDataSource & ";User ID=" & strUserID & ";Password=" & strPassword & ";" 
    objConn.Open 

    Set vfnc_StartConnection = objConn 
End Function