Конкатенировать диапазон с одним значением

Question

Я пытаюсь объединить диапазон с одним значением.

Почему это не вставляет переменную «комбо» в ячейку?

Больше Объяснение (Скопировано из комментариев)

В основном я хочу, чтобы принимать значения в каждой ячейке столбца С и добавить 00000 к концу всех из них. поэтому, если C1 было 50, я хочу, чтобы конечный результат был скопирован поверх 50 и заменил C1 на 5000000, если C2 был 575, тогда замените это на 57500000, все по всему диапазону данных в C.

Я бы предпочёл его вставьте значения в том же столбце, если это невозможно. Тогда для примера, который вы дали, я бы хотел, чтобы D1 = AAA00000, D2 = BBB00000, D3 = CCC00000 и т. Д.

Answer 1

Это то, что вы пытаетесь? Я дал вам два пути.

WAY 1

Sub Sample() 
    Dim ws As Worksheet 
    Dim lRow As Long 
    Dim rng As Range 

    '~~> Change this to the relevant worksheet 
    Set ws = ThisWorkbook.Sheets("Sheet1") 

    With ws 
     '~~> Get last row in Col C 
     lRow = .Range("C" & .Rows.Count).End(xlUp).Row 

     '~~> Construct your range 
     Set rng = .Range("C3:C" & lRow) 

     '~~> Multiply all the cells in the range with 100000 
     '~~> so that 55 become 5500000, 123 becomes 12300000 and so on 
     rng.Value = Evaluate(rng.Address & "*100000") 
    End With 
End Sub 

WAY 2

Тип 100000 в ячейке D1, а затем запустить этот макрос

Sub Sample() 
    Dim ws As Worksheet 
    Dim lRow As Long 
    Dim rng As Range 

    '~~> Change this to the relevant worksheet 
    Set ws = ThisWorkbook.Sheets("Sheet1") 

    With ws 
     '~~> Get last row in Col C 
     lRow = .Range("C" & .Rows.Count).End(xlUp).Row 

     '~~> Construct your range 
     Set rng = .Range("C3:C" & lRow) 

     '~~> This cell has 100000 
     .Range("D1").Copy 

     '~~> Paste Special Value/Multiply 
     rng.PasteSpecial Paste:=xlPasteValues, _ 
         Operation:=xlMultiply, _ 
         SkipBlanks:=False, _ 
         Transpose:=False 

     Application.CutCopyMode = False 
    End With 
End Sub