Изменение значений одной ячейки на основе другой в Excel

Question

Я новичок в Excel и VBA. Я делаю список проектов, у меня есть два столбца для состояния, Status и Status in Words. В первом мне нужно ввести статус в виде чисел, например. 50% или 80%, а во втором Мне нужно ввести статус проекта словами: Open, Closed, In Progress и т. Д. Моя проблема в том, что когда я пишу 50% в первом столбце, статус в другом столбце должен автоматически меняться до In Progress и наоборот, если я ввожу Closed во второй столбец, то статус в первом столбце должен измениться на 100%. Может ли кто-нибудь сказать мне, как это сделать в Excel vba.

Answer 1

Это может сработать. Измените 1 на свой нижний номер столбца и 2 на свой больший номер столбца. Я не мог понять, как сказать Excel, чтобы проверить, соответствует ли она «100%» или «50%», поэтому мне пришлось использовать 1 и .5. Если кто знает, не стесняйтесь редактировать или прокомментировать!

'This is a global variable, prevents endless loops in worksheet change. 
Dim running As Boolean 

'When any change is made on the worksheet, sends target as the changed cell 
Private Sub Worksheet_Change(ByVal Target As Range) 
    'Checks to see if a worksheet change is already running, if it is, then it quits 
    If running = True Then Exit Sub 
    'We are running code now, so prevent endless loops 
    running = True 
    Dim YourFirstColumn, YourOtherColumn As Integer 

    'Set to your values 
    YourFirstColumn = 1 
    YourOtherColumn = 2 

    'If this is a column you want to change 
    If Target.Column = YourFirstColumn Then 

     'Change values 
     If Target.Value = "In Progress" Then 
      Target.Offset(0, Abs(YourFirstColumn - YourOtherColumn)).Value = "50%" 
     ElseIf Target.Value = "Closed" Then 
      Target.Offset(0, Abs(YourFirstColumn - YourOtherColumn)).Value = "100%" 
     End If 

    'If this is the other column you want to change 
    ElseIf Target.Column = YourOtherColumn Then 

     'Change values 
     If Target.Value = 0.5 Then 
      Target.Offset(0, -Abs(YourFirstColumn - YourOtherColumn)).Value = "In Progress" 
     ElseIf Target.Value = 1 Then 
      Target.Offset(0, -Abs(YourFirstColumn - YourOtherColumn)).Value = "Closed" 
     End If 
    End If 
    running = false 
End Sub