batch command, чтобы найти определенный размер папки

Question

Я пытаюсь найти размер, который определенная папка говорит «log» внутри моего текущего каталога. предложите мне командные команды, используемые только для получения размера папки «Журнал».

Answer 1

я предлагаю одну команду окна его отображения рекурсивно все размер файла и последняя строка показать общий размер папки

«реж/S журнал»

Answer 2

@echo off 
for /f "tokens=2 delims=," %%a in ('dir /s /-c log\^|findstr /b /c:" "') do (
    for /f "tokens=1" %%b in ("%%a") do set x=%%b& goto :done 
) 
:done 
echo %x% Bytes in this folder (and subfolders) 

лексем (ы) может быть необходимо адаптировать на местный язык.

Answer 3

Вы можете попробовать это (/ VBScript Пакетный файл):

@echo off 
Title Get Size of Folder and its subfolders 
set "Folder=C:\log" 
Set Log=Folder_Size.txt 
(
    echo The size of "%Folder%" is 
    Call :GetSize "%Folder%" 
)> "%Log%" 
For /f "delims=" %%a in ('Dir "%Folder%" /AD /b /s') do ( 
    (
     echo The size of "%%a" is 
     Call :GetSize "%%a" 
    )>> "%Log%" 
) 
start "" "%Log%" 
::*********************************************************************** 
:GetSize 
(
echo wscript.echo GetSize("%~1"^) 
echo Function GetSize(MyFolder^) 
echo Set fso = CreateObject("Scripting.FileSystemObject"^) 
echo Set objFolder= fso.GetFolder(MyFolder^) 
echo GetSize = FormatSize(objFolder.Size^) 
echo End Function 
echo '******************************************************************* 
echo 'Function to format a number into typical size scales 
echo Function FormatSize(iSize^) 
echo aLabel = Array("bytes", "KB", "MB", "GB", "TB"^) 
echo For i = 0 to 4 
echo  If iSize ^> 1024 Then 
echo   iSize = iSize/1024 
echo  Else 
echo   Exit For 
echo  End If 
echo Next 
echo FormatSize = Round(iSize,2^) ^& " " ^& aLabel(i^) 
echo End Function 
echo '******************************************************************* 
)>%tmp%\Size.vbs 
Cscript /NoLogo %tmp%\Size.vbs 
Del %tmp%\Size.vbs 
Exit /b 
::*********************************************************************** 

Edit: On 27/09/2016 Только для одной папки и не рекурсивной:

@echo off 
mode con cols=67 lines=5 & Color 0A 
Title Get Size of Folder and its subfolders 
set "Folder=C:\HackooTest" 
Set Log=%Folder%_Size.txt 
(
    echo The size of "%Folder%" is 
    Call :GetSize "%Folder%" 
)> "%Log%" 

echo The size of "%Folder%" is 
Call :GetSize "%Folder%" 
pause & Start "" "%Log%" 
exit 
::*********************************************************************** 
:GetSize 
(
echo wscript.echo GetSize("%~1"^) 
echo Function GetSize(MyFolder^) 
echo Set fso = CreateObject("Scripting.FileSystemObject"^) 
echo Set objFolder= fso.GetFolder(MyFolder^) 
echo GetSize = FormatSize(objFolder.Size^) 
echo End Function 
echo '******************************************************************* 
echo 'Function to format a number into typical size scales 
echo Function FormatSize(iSize^) 
echo aLabel = Array("bytes", "KB", "MB", "GB", "TB"^) 
echo For i = 0 to 4 
echo  If iSize ^> 1024 Then 
echo   iSize = iSize/1024 
echo  Else 
echo   Exit For 
echo  End If 
echo Next 
echo FormatSize = Round(iSize,2^) ^& " " ^& aLabel(i^) 
echo End Function 
echo '******************************************************************* 
)>%tmp%\Size.vbs 
Cscript /NoLogo %tmp%\Size.vbs 
Del %tmp%\Size.vbs 
Exit /b 
::***********************************************************************