Синхронизация процессов путем блокировки файла

Question

Один из моих скриптов - установка компонента. При параллельном запуске один и тот же скрипт пытается установить один и тот же компонент, поэтому я подумал о синхронизации процесса, заблокировав файл во время установки скрипта и дожидаясь, пока другой скрипт что-то устанавливает.

код будет выглядеть следующим образом:

# this will create a file handler on a file from TEMP dir with the 
# name of the component; if it doesn't exist in TEMP dir, it will create it 

my $file = $ENV{"TEMP"}. "\\" . $componentName; 
open (my $fh, ">", "$file") or die "Couldn't open file!"; 

# this will apply an exclusive lock meaning that if another process 
# already locked the file, it will wait until the lock is removed 

flock($fh, 2) or die "Failed to lock the file"; 

# install the component.. 

# closing the file handle automatically removes the lock 
close $fh; 

Я обеспокоен ситуацией, когда скрипт блокирует файл и начинает установку и второй сценарий приходит и пытается создать дескриптор файла на заблокированном файл. Я не видел никаких ошибок, но я не хочу ничего пропустить.

Будет ли проблема с этим?

Answer 1

Важно помнить, что «открытая» будет работать в любом случае, потому что это не проверяет блокировку. Это операция flock, которая будет блокироваться до тех пор, пока блокировка не будет отпущена.

И это должно работать нормально, хотя после того, как освобожден - вы можете проверить, нужно ли все же выполнить установку, если только вам не нужно делать это дважды - например. если остальная часть скрипта использует/полагается на него.

Также есть ли другие источники «установки», которые не являются вашим скриптом, что может вызвать такую ​​же проблему? Замок - это консультативная вещь.

Было бы улучшение стиля в вашей программе также:

• Теста $ENV{'TEMP'} увидеть, что она существует, и по умолчанию (или не), если он не делает.
• use Fcntl qw (:flock); потому что тогда вы можете flock ($fh, LOCK_EX);, чтобы было ясно, что вы делаете эксклюзивный замок.
• В качестве разделителя файлов вы используете \\. Вероятно, это лучше, если вы использовали что-то вроде File::Spec, чтобы сделать это по причинам мобильности.
• Вы можете использовать LOCK_NB для неблокирования: flock ($fh, LOCK_EX | LOCK_NB), а затем просто пропустить, если он заблокирован.

Answer 2

Блокировка не препятствует открытию или изменению файла; это предотвращает его блокировку.

Это означает, что open не подведет, и он будет сжимать файл, даже если он заблокирован и все еще используется. Если блокировка предназначена для защиты доступа к файлу (т. Е. Если программы фактически записываются в заблокированный файл), вы хотите использовать sysopen, чтобы избежать сглаживания файла, если он уже существует ^[1].

use Fcntl qw(LOCK_EX O_CREAT O_WRONLY); 

# Open the file without clobbering it, creating it if necessary. 
sysopen(my $fh, $qfn, O_WRONLY | O_CREAT) 
    or die($!); 

# Wait for the file to become available. 
flock($fh, LOCK_EX) 
    or die($!); 

truncate($fh, 0) 
    or die($!); 

... 

или

use Fcntl qw(LOCK_EX LOCK_NB O_CREAT O_WRONLY); 

# Open the file without clobbering it, creating it if necessary. 
sysopen(my $fh, $qfn, O_WRONLY | O_CREAT) 
    or die($!); 

# Check if the file is locked. 
flock($fh, LOCK_EX | LOCK_NB) 
    or die($!{EWOULDBLOCK} ? "File already in use\n" : $!); 

truncate($fh, 0) 
    or die($!); 

... 

---

1. Вы можете также использовать open(my $fh, '>>', $qfn), если вы не против того, файл в режиме добавления.