Уникальные узлы фильтра XSLT внутри группы с использованием метода группировки Muenchian

Question

В качестве ссылки я следую этой статье о Muenchian Grouping Method.

В моей проблеме в пределах каждой группы некоторые значения для узла <forename> могут быть дублированы, в то время как я хочу фильтровать уникальные значения. Я пробовал применять критерии выбора forename[not(.=preceding-sibling::forename)] , но это не работает, так как я вижу дубликаты на выходе.

XSLT, который я тестирую, следует (что в основном точно так же, как в статье выше, строка «изолированная», где применяется дополнительный фильтр).

Я, очевидно, ошибаюсь. В чем проблема?

<?xml version="1.0"?> 
<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

    <xsl:output indent="yes" method="text"/> 
    <xsl:key name="contacts-by-surname" match="contact" use="surname" /> 
    <xsl:template match="records"> 
     <xsl:for-each select="contact[count(. | key('contacts-by-surname', surname)[1]) = 1]"> 
      <xsl:sort select="surname" /> 
      <xsl:value-of select="surname" /> 
      <xsl:for-each select="key('contacts-by-surname', surname)"> 
       <xsl:sort select="forename" /> 


       <xsl:value-of select="forename[not(.=preceding-sibling::forename)]" /> 


      </xsl:for-each> 
     </xsl:for-each> 
    </xsl:template> 
</xsl:stylesheet> 

Answer 1

Вы могли бы сделать два уровня группировки с другим ключом

<?xml version="1.0"?> 
<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

    <xsl:output indent="yes" method="text"/> 
    <xsl:key name="contacts-by-surname" match="contact" use="surname" /> 
    <xsl:key name="contacts-by-full-name" match="contact" use="concat(surname, '|', forename)" /> 
    <xsl:template match="records"> 
     <xsl:for-each select="contact[count(. | key('contacts-by-surname', surname)[1]) = 1]"> 
      <xsl:sort select="surname" /> 
      <xsl:value-of select="surname" /> 
      <xsl:for-each select="key('contacts-by-surname', surname) 
       [count(. | key('contacts-by-full-name', 
           concat(surname, '|', forename'))[1]) = 1]"> 
       <xsl:sort select="forename" /> 
       <xsl:value-of select="forename" /> 
      </xsl:for-each> 
     </xsl:for-each> 
    </xsl:template> 
</xsl:stylesheet> 

Здесь в каждой группе surname я делаю другую Muenchian группировку на полное имя (фамилия | Forename) и извлекая только первый экземпляр каждого имени в наборе контактов с этой фамилией.