Обработка ошибок с использованием Perl Tkx

Question

Я работаю над приложением Perl Tkx, и у меня возникают проблемы с получением полезных/правильных сообщений об ошибках. Я пытаюсь использовать croak, поэтому он скажет мне, где именно он терпит неудачу, но каждый раз, когда он скрипит, он просто говорит, что ошибка находится «на C: /Perl64/lib/Tkx.pm, строка 347.»

Я написал очень простой сценарий, чтобы продемонстрировать, что происходит:

---

#!/usr/bin/perl 

use strict; 
use warnings; 

use Carp; 
use Tkx; 

my $mw = Tkx::widget->new("."); 
my $b = $mw->new_button(
    -text => "Hello, world", 
    -command => sub { croak; }, 
); 
$b->g_pack; 

Tkx::MainLoop(); 

---

Когда я запускаю этот скрипт и нажмите на кнопку Я получаю следующее всплывающее окно:

Как я могу сделать ошибки обработки Tkx похожими на использование croak в регулярный скрипт Perl? есть ли способ заставить каркас печатать на STDOUT или STDERR?

---

EDIT:

Майкл Карман приносит хорошую точку, как правило, с графическим интерфейсом консоль будет подавлено, и пользователь никогда не увидит сообщение об ошибке отправлено в STDOUT или STDERR, но то, что о поиске способ изменить текст в диалоговом окне «Ошибка приложения», чтобы сказать что-то полезное? Это возможно?

Текст не обязательно должен быть полезен конечному пользователю, но должен быть по крайней мере понятен программисту, чтобы они знали, где искать проблему, когда она сообщается конечным пользователем.

---

EDIT2:

Хорошо оказывается, что с помощью die или confess вместо croak печатает сообщение более полезной ошибке в окне «Ошибка приложения», но когда я нажимаю «ОК» программа просто продолжается и фактически не умирает. Как я могу «убить его до тех пор, пока он не погибнет» и не оставит его мертвым?

---

ВОЗМОЖНОЕ РЕШЕНИЕ:

Вот возможное решение построено прочь ответ Майкл Карман в. Я изменил его немного, потому что я думаю, что MessageBox выглядит немного лучше :)

#!/usr/bin/perl 

use strict; 
use warnings; 

use Tkx; 
use Carp; 

my $mw = Tkx::widget->new("."); 
my $b = $mw->new_button(
    -text => "Hello, world", 
    -command => sub { die "uh-oh"; }, 
); 
$b->g_pack; 

Tkx::eval(<<'EOT'); 
proc bgerror {message} { 
    tk_messageBox -title "Application Error" -message $message -icon error -type ok 
    destroy . 
} 
EOT 

Tkx::MainLoop(); 

До сих пор это лучшее решение, но 5 дней все еще остаются в щедрот так держать эти ответы приходят!

Answer 1

croak сообщения об ошибках, с точки зрения вызывающего абонента. Используйте die, чтобы сообщать об ошибках с точки зрения вашего кода.

croak обычно используется при написании модулей, чтобы вы могли сообщить о проблемах в том, как используется ваш код. (например, для проверки аргументов). Программирование графического интерфейса является своего рода зеркальным отображением этого. Вместо того, чтобы писать библиотеку для кого-то другого, вы вводите свой код в библиотеку, написанную кем-то другим. Когда вы передаете ссылку на код -command, вызывающий становится Tkx, поэтому лучше сообщать о любых ошибках с точки зрения вашего кода.

Tkx обнаруживает фатальные ошибки в обратных вызовах и сообщает о них через диалоговое окно «Ошибка приложения», которое вы видите. Это не редкость для отключения GUI-приложений от консоли, что означает, что STDOUT и STDERR закрыты, и все написанные на них сообщения теряются. Без диалога ваше приложение просто исчезнет, ​​и пользователь не будет знать, почему.

например.

use Tkx; 

my $mw = Tkx::widget->new("."); 
my $b = $mw->new_button(
    -text => "Hello, world", 
    -command => sub { die "uh-oh" }, 
); 
$b->g_pack; 

Tkx::MainLoop(); 

Когда я запускаю этот (и нажмите на кнопку) диалоговое сообщение

uh-oh at c:\temp\foo.pl line 9. 

Если вам нужен полный контроль над тем, как Tk обрабатывает ошибки вы можете переопределить обработчик по умолчанию. Уловка заключается в том, что вы должны сделать это в Tcl. Вот минимальная версия, чтобы создать диалог с сообщением об ошибке и выйти из приложения, когда оно закрыто.

Tkx::eval(<<'EOT'); 
proc bgerror {message} { 
    tk_dialog .error "Error" $message [] 0 Close 
    destroy . 
} 
EOT 

Answer 2

Следующие сценарии печатает сообщение об ошибке в STDOUT:

use strict; 
use warnings; 

use Carp; 
use Tkx; 

my $mw = Tkx::widget->new("."); 
my $b = $mw->new_button(
    -text => "Hello, world", 
    -command => \&error_test, 
); 
$b->g_pack; 

Tkx::MainLoop(); 

sub error_test { 
    eval { 
     confess; 
    }; 
    print "$@\n"; 
} 

Выход:

at ./p.pl line 20. 
    eval {...} called at ./p.pl line 19 
    main::error_test() called at /home/hakon/perl5/lib/perl5/Tkx.pm line 347 
    eval {...} called at /home/hakon/perl5/lib/perl5/Tkx.pm line 347 
    Tkx::i::DoOneEvent(0) called at /home/hakon/perl5/lib/perl5/Tkx.pm line 56 
    Tkx::MainLoop() called at ./p.pl line 16 

Редактировать

Следующая может быть использована для печати сообщения об ошибке в тексте поле Tk GUI:

use strict; 
use warnings; 
use Carp; 
use Tkx; 

my $mw = Tkx::widget->new("."); 
my $b = $mw->new_button(
    -text => "Hello, world", 
    -command => \&error_test, 
); 
$b->g_grid(-column => 0, -row => 0); 
my $text = $mw->new_tk__text(-width => 100, -height => 30); 
$text->g_grid(-column => 0, -row => 1); 

Tkx::MainLoop(); 

sub error_test { 
    eval { 
     confess; 
    }; 
    print "$@\n"; 
    $text->insert("end", "$@\n"); 
} 

Редактировать

Чтобы уничтожить окно после того, как сообщение об ошибке было показано, вы можете использовать:

use strict; 
use warnings; 
use Carp; 
use Tkx; 

my $mw = Tkx::widget->new("."); 
my $b = $mw->new_button(
    -text => "Hello, world", 
    -command => \&error_test, 
); 
$b->g_pack; 

Tkx::MainLoop(); 

sub error_test { 
    eval { 
     confess; 
    }; 
    Tkx::tk___messageBox(-message => "$@"); 
    $mw->g_destroy; 
}