Приращение целочисленной переменной в цикле

Question

У меня есть «i», которая является целочисленной переменной, и я бы хотел сделать цикл, который увеличивает «i» с 40000 до 90000, добавляя 1000 каждый раз. Каждый результат появится в ComboBox.

Пример: 40000 - 41000 - 42000 - 43000 - ... - 88000 - 89000 - 90000

Мой код выглядит следующим образом:

var i:integer; 
begin 
for i:= 40000 to 90000 do 
    begin 
    ComboBox1.AddItem(IntToStr(i), nil); //until here the code works 
    Inc(i, 1000);       
    end; 

Есть ли у вас какие-либо предложения?

Answer 1

Вы не можете изменить переменную цикла for внутри цикла.

Что вы хотите, это:

for i := 0 to 50 do 
    ComboBox1.AddItem(IntToStr(40000 + 1000 * i), nil) 

Но! Это довольно неэффективно. Вы должны рассмотреть

ComboBox1.Items.BeginUpdate; 
for i := 0 to 50 do 
    ComboBox1.Items.Add(IntToStr(40000 + 1000 * i)); 
ComboBox1.Items.EndUpdate; 

Answer 2

Альтернативы @ AndreasRejbrand, решение которого является while петли:

i := 40000; 
while i <= 90000 do 
begin 
    ComboBox1.AddItem(IntToStr(i), nil); 
    Inc(i, 1000); 
end; 

или `повторить ':

i := 40000; 
repeat 
    ComboBox1.AddItem(IntToStr(i), nil); 
    Inc(i, 1000); 
until i > 90000; 

Answer 3

Компилятор запрещает изменять переменный цикл.

Существует способ включить поддержку петли for..step. У вас должна быть версия Delphi, поддерживающая дженерики (Delphi-2009 +).

Просто сделать это заявление в полезности единицы:

Type 
    ForLoop = record 
    class procedure Step(Start,Stop,AStep : Integer; 
          ALoop : TProc<Integer>); static; 
    end; 

class procedure ForLoop.Step(Start,Stop,AStep : Integer; ALoop: TProc<Integer>); 
begin 
    while (start <= stop) do 
    begin 
    ALoop(start); 
    Inc(Start,AStep); 
    end; 
end; 

---

И использовать его как это:

ForLoop.Step(40000,90000,1000, 
    procedure (i : Integer) 
    begin 
    ComboBox1.AddItem(IntToStr(i), nil); 
    end 
); 

---

В Delphi 2005, были добавлены методы по записи плюс перечисление for in.

Зная это, можно реализовать другой цикл цикла с функциональностью шага.

type 
    Range = record 
    private 
    FCurrent,FStop,FStep : Integer; 
    public 
    constructor Step(Start,Stop,AnIncrement : Integer); 
    function GetCurrent : integer; inline; 
    function MoveNext : boolean; inline; 
    function GetEnumerator : Range; // Return Self as enumerator 
    property Current : integer read GetCurrent; 
    end; 

function Range.GetCurrent: integer; 
begin 
    Result := FCurrent; 
end; 

function Range.GetEnumerator: Range; 
begin 
    Result := Self; 
end; 

function Range.MoveNext: boolean; 
begin 
    Inc(FCurrent,FStep); 
    Result := (FCurrent <= FStop); 
end; 

constructor Range.Step(Start,Stop,AnIncrement: Integer); 
begin 
    Self.FCurrent := Start-AnIncrement; 
    Self.FStop := Stop; 
    Self.FStep := AnIncrement; 
end; 

И теперь вы можете написать:

for i in Range.Step(40000,90000,1000) do 
    ComboBox1.AddItem(IntToStr(i), nil); 

Копать во внутренние работы этого примера, см more-fun-with-enumerators.

---

Легко реализовать версию двух примеров .StepReverse выше, и я оставлю это в качестве упражнения для заинтересованного читателя.

Answer 4

Мы также можем сделать петлю от 40 до 90 и умножить показатель с 1000

var i: integer; 
begin 
    for i:= 40 to 90 do 
    begin 
     ComboBox1.AddItem(IntToStr(i*1000), nil);  
    end;     
end;