TSQL - создать хранимую процедуру внутри оператора транзакции

Question

У меня есть скрипт sql, который настроен на roll to production. Я объединил различные проекты в отдельные транзакции. В каждой транзакции мы создали хранимые процедуры. Я получаю сообщения об ошибках

Msg 156, Level 15, State 1, Line 4 Неверный синтаксис рядом с ключевым словом «procedure».

Я создал этот пример сценарий для иллюстрации

Begin Try 
Begin Transaction 
    -- do a bunch of add/alter tables here 
    -- do a bunch of data manipulation/population here 

    -- create a stored proc 
    create procedure dbo.test 
    as 
    begin 
    select * from some_table 
    end 
Commit 
End Try 
Begin Catch 
    Rollback 
    Declare @Msg nvarchar(max) 
    Select @Msg=Error_Message(); 
    RaisError('Error Occured: %s', 20, 101,@Msg) With Log; 
End Catch 

ошибка, кажется, подразумевает, что я не могу создавать хранимые проки внутри транзакции, но я не нахожу никаких документов, которые говорят иначе (возможно, Google ISN Сегодня не бывает.

Answer 1

попробовать делает create procedure в EXEC('...'), как это:

Begin Try 
Begin Transaction 
    -- do a bunch of add/alter tables here 
    -- do a bunch of data manipulation/population here 

    -- create a stored proc 
    EXEC ('create procedure dbo.test 
    as 
    begin 
    select * from some_table 
    end') 
Commit 
End Try 
Begin Catch 
    Rollback 
    Declare @Msg nvarchar(max) 
    Select @Msg=Error_Message(); 
    RaisError('Error Occured: %s', 20, 101,@Msg) With Log; 
End Catch 

GO 

Answer 2

я припоминаю, вы не можете делать такие вещи, как создавать, изменять или удалять схемы базы данных объектов — включая хранимые процедуры — внутри транзакции (так как такая структурная изменения не являются транзакционными: вы не можете откатить их с изменениями данных).

Answer 3

Вы не можете написать свой сценарий таким образом, поскольку существует множество операторов, которые должны запускаться в их собственной партии. Вместо этого, я рекомендовал бы делать что-то похожее на SQL, как Red-Gate Сравним строит свои сценарии:

Set Xact_Abort On 
GO 
Begin Transaction 
GO 
If object_id('tempdb..#tmpErrors') is not null 
    Drop Table #tmpErrors 
GO 
Create Table #tmpErrors([Error] int not null) 
GO 
Create Procedure dbo.Test 
As 
Begin 
    --.... 
End 
GO 
If @@Error <> 0 AND @@TranCount >0 Rollback Transaction 
GO 
IF @@TranCount = 0 Begin Insert #tmpErrors (Error) Select 1 Begin Transaction End 
GO 

-- more statements 

GO 
If @@Error <> 0 AND @@TranCount >0 Rollback Transaction 
GO 
IF @@TranCount = 0 Begin Insert #tmpErrors (Error) Select 1 Begin Transaction End 
GO 

--..... 

IF NOT EXISTS(SELECT * FROM #tmpErrors) 
    BEGIN 
     PRINT 'The database update succeeded' 
     IF @@TRANCOUNT > 0 COMMIT TRANSACTION 
    END 
ELSE 
    BEGIN 
     PRINT 'The database update failed' 
     IF @@TRANCOUNT > 0 ROLLBACK TRANSACTION 
    END 
GO 

DROP TABLE #tmpErrors 
GO 

Answer 4

Существуют различные проблемы, связанные с решением, предложенным КМ:

• Если содержание того, что вы поместить в ваш вызов EXEC() неверно семантически (например, вы положили несуществующую таблицу в FROM внутри хранимой процедуры), что ошибка не пузырится и транзакция не откат.

• Если содержимое того, что вы помещаете в ваш вызов EXEC(), является синтаксически неправильным (например, вы помещаете SELECTT вместо SELECT внутри хранимой процедуры), транзакция кажется откатанной, но полностью критическая ошибка пузырится вверх :

  A transport-level error has occurred when receiving results from the server. (provider: TCP Provider, error: 0 - The specified network name is no longer available.) 
  

Так что я до сих пор в убыток, как создать процедуру внутри транзакции, но до сих пор сделка и попытка прилов быть полезным.