У меня есть zip-файл с именем data.zip, и я хотел бы узнать, есть ли пакетный код, который может отправить его по электронной почте [email protected] Это часть программы, поэтому, если она включает в себя дополнительное программное обеспечение, мне должно быть разрешено ее распространять с программным обеспечением. Он может быть отправлен как приложение. Пакетный файл повышен.Отправка файлов в партию
(из сообщения Usenet) Попробуйте этот командный файл - он был протестирован с помощью gmail и использует SSL и порт 465 для отправки.
Выполните команду следующим образом, но эта команда находится на одной линии.
email.bat [email protected] [email protected] "This subject is about emails" "This is the body of the email" smtp.gmail.com [email protected] password "d:\folder\attachment.txt"
[email protected] - ваш адрес электронной почты.
[email protected] - адрес электронной почты получателя.
"d:\folder\attachment.txt" это приложение для отправки.
::email.bat:::::::::::::::::::::::::::::::::::::::::::::::::::::
@echo off
setlocal
:: defaults
set [email protected]
set [email protected]
set Subj="email test %date% %time%"
set Body="did it work? %date% %time%"
set Serv=mail.server.com.au
set Auth=user
set Pass=pass
set fileattach=
:: if command line arguments are supplied then use them
if "%~7" NEQ "" (
set From=%1
set To=%2
set Subj="%~3"
set Body="%~4"
set Serv=%5
set "Auth=%~6"
set "Pass=%~7"
set "fileattach=%~8"
)
call :createVBS "email-bat.vbs"
call :send %From% %To% %Subj% %Body% %Serv% %Auth% %Pass%
echo email has been sent (if parameters were correct)
pause
del "%vbsfile%" 2>nul
goto :EOF
:send
cscript.exe /nologo "%vbsfile%" %1 %2 %3 %4 %5 %6 %7
goto :EOF
:createVBS
set "vbsfile=%~1"
del "%vbsfile%" 2>nul
set cdoSchema=http://schemas.microsoft.com/cdo/configuration
echo >>"%vbsfile%" Set objArgs = WScript.Arguments
echo >>"%vbsfile%" Set objEmail = CreateObject("CDO.Message")
echo >>"%vbsfile%" objEmail.From = objArgs(0)
echo >>"%vbsfile%" objEmail.To = objArgs(1)
echo >>"%vbsfile%" objEmail.Subject = objArgs(2)
echo >>"%vbsfile%" objEmail.Textbody = objArgs(3)
if defined fileattach echo >>"%vbsfile%" objEmail.AddAttachment "%fileattach%"
echo >>"%vbsfile%" with objEmail.Configuration.Fields
echo >>"%vbsfile%" .Item ("%cdoSchema%/sendusing") = 2 ' not local, smtp
echo >>"%vbsfile%" .Item ("%cdoSchema%/smtpserver") = objArgs(4)
echo >>"%vbsfile%" .Item ("%cdoSchema%/smtpserverport") = 465
echo >>"%vbsfile%" .Item ("%cdoSchema%/smtpauthenticate") = 1 ' cdobasic
echo >>"%vbsfile%" .Item ("%cdoSchema%/sendusername") = objArgs(5)
echo >>"%vbsfile%" .Item ("%cdoSchema%/sendpassword") = objArgs(6)
echo >>"%vbsfile%" .Item ("%cdoSchema%/smtpusessl") = True
echo >>"%vbsfile%" .Item ("%cdoSchema%/smtpconnectiontimeout") = 25
echo >>"%vbsfile%" .Update
echo >>"%vbsfile%" end with
echo >>"%vbsfile%" objEmail.Send
:end
Нет, он не отправляет файлы, которые являются только текстом – 09stephenb
Принимаемый ответ (с использованием BLAT) также будет поддерживать отправку вложений. Есть вопросы по SO (http://stackoverflow.com/questions/1172200/how-can-i-send-a-pdf-file-as-blat-attachment) об использовании BLAT с вложениями. –