Найти позиции данных символов

Question

Я хочу найти позиции некоторых символов для их обработки без использования чудовищного рекурсивного и неэффективного регулярного выражения. Вот как я это делаю:

my @charpos=(); 
s/(?=([«»\n]))/push @charpos, [$1, 0+($-[0])]; "";/ge; 
# sort {$a->[1] <=> $b->[1]} @charpos; 

Но это решение использует «заменитель» оператор заменить с пустой строкой, это нормально? Должна ли прокомментированная строка быть раскоментирована?

Answer 1

Для вашей общей проблемы вы можете изучить sub parse_line в Text::ParseWords.

В контексте кода вы дали в вашем вопросе, я бы избежать изменения строки источника:

#!/usr/bin/perl 

use utf8; 
use strict; use warnings; 

my $x = q{«...«...»...«...»...»}; 

my @pos; 

while ($x =~ /([«»\n])/g) { 
    push @pos, $-[1]; 
} 

use YAML; 
print Dump \@pos; 

Answer 2

В общем, чтобы найти позиции символов в строке, вы можете сделать это следующим образом:

my $str = ...; 
my @pos; 
push @pos, pos $str while $str =~ /(?=[...])/g; 

И затем все позиции, где регулярное выражение совпавшие будет @pos. По крайней мере, с помощью этого метода вы не постоянно переписываете свою исходную строку.

Answer 3

Там больше чем один способ кожи кошки:

#!/usr/bin/env perl 

use 5.010; 
use utf8; 
use strict; 
use warnings qw< FATAL all >; 
use autodie; 
use open qw< :std OUT :utf8 >; 

END { close STDOUT } 

my @pos =(); 
my $string = q{«...«...»...«...»...»}; 
($string .= "\n") x= 3; 

say "string is:\n$string"; 

for ($string) { 
    push @pos, pos while m{ 
     (?= [«»\n]) 
    }sxg;; 
} 
say "first test matches \@ @pos"; 

@pos =(); 

## this smokes :) 
"ignify" while $string =~ m{ 
    [«»\n] 
    (?{ push @pos, $-[0] }) 
}gx; 
say "second test matches \@ @pos"; 

__END__ 
string is: 
«...«...»...«...»...» 
«...«...»...«...»...» 
«...«...»...«...»...» 

first test matches @ 0 4 8 12 16 20 21 22 26 30 34 38 42 43 44 48 52 56 60 64 65 
second test matches @ 0 4 8 12 16 20 21 22 26 30 34 38 42 43 44 48 52 56 60 64 65 

Но, пожалуйста, кредит Sinan.

Answer 4

Регулярное выражение для скитирования кошки, чтобы добавить в руководство. Является ли это чудовищное в глазах смотрящего:

use List::Util q/min/; 
my @targets = ('«','»',"\n"); 
my $x = q{«...«...»...«...»...»}; 
my $pos = min map { my $z = index($x,$_); $z<0?Inf:$z } @targets; 
my @pos; 
while ($pos < Inf) { 
    push @pos, $pos; 
    $pos = min map { my $z = index($x,$_,$pos+1); $z<0?Inf:$z } @targets; 
}