Создание словаря с VBA

Question

Я пытаюсь создать словарь списков. Я привык к этому в python, но в vba у меня возникают трудности. данные в колонках А и В (я буду использовать диапазон с конца (xldown) вместо жесткого кодирования A1: A4 это только в качестве примера), и они выглядят примерно так:

A Apple 
A Banana 
B Carrot 
B Juice 

По существу я m, желающий создать словарь, который выглядит (в формате python как: {A: [Apple, Bannana], B: [Carrot, Juice]}

Конечным результатом является то, что я хочу вставить значения словаря в другой столбец C, который будет выглядеть следующим образом:

A Apple Apple/Banana 
A Banana Apple/Banana 
B Carrot Carrot/Juice 
B Juice Carrot/Juice 

Я пытался используя вложенный цикл через varrays, но он не распознал относительные позиции столбца A и B. Мне было интересно, что лучший способ сделать это в VBA?
Спасибо.

Answer 1

Вы можете использовать только VBA или смешивать с UDF.

Рассмотрим первоначально у вас есть (чтобы продемонстрировать один из вариантов):

Создайте модуль и поместить его в:

Option Explicit 

Private lRow As Long 
Private oDict As Object 

Private Sub CreateDict() 
    Dim arrValues As Variant, oKey As Variant, oValue As Variant, i As Long 

    If oDict Is Nothing Then 
     lRow = Worksheets("Sheet2").UsedRange.Rows.Count 
     Set oDict = CreateObject("Scripting.Dictionary") 
    Else 
     If lRow <> Worksheets("Sheet2").UsedRange.Rows.Count Then oDict.RemoveAll ' Remove old items 
    End If 
    ' Add items to the dictionary 
    ' Load values of used range to memory 
    arrValues = Worksheets("Sheet2").UsedRange.Value 
    ' Assuming the Key is on first column and Value is on next 
    For i = 1 To UBound(arrValues) 
     oKey = arrValues(i, 1) 
     oValue = arrValues(i, 2) 
     If Len(oKey) > 0 Then 
      If oDict.Exists(oKey) Then 
       ' Append Value to existing key 
       oDict.Item(oKey) = oDict.Item(oKey) & "/" & oValue 
      Else 
       ' Add Key and value 
       oDict.Add oKey, oValue 
      End If 
     End If 
    Next 
End Sub 

Function GetList(ByVal oRange As Range) As String 
    If lRow <> Worksheets("Sheet2").UsedRange.Rows.Count Then Set oDict = Nothing 
    If oDict Is Nothing Then CreateDict 
    GetList = oDict.Item(oRange.Value) 
End Function 

Макрос выше, чтобы создать список словарей. Затем в следующем столбце используйте формулу для вызова UDF GetList, например.

Auto Fill ОДС, чтобы получить результат, который вы хотите:

---

Есть плюсы и минусы с помощью UDF, но я полагаю, вы можете изменить его только VBA (новый Sub и цикл через первый столбец).

Answer 2

Используя комбинацию формул и VBA, вы можете достичь ожидаемых результатов. Начиная с ячейкой C1, а затем перетащить вниз до конца вашего стола места следующей формулы:

=stringconcat("/",IF($A:$A=A1,$B:$B,"")) 

Это вставляется как формула массива с помощью CTRL + SHIFT + ENTER. Объясняя логику из IF, для каждой строки в столбце A:A, которая равна значению этой строки («A» в представленном примере), она будет извлекать ее в массив (возврат, если истинный вариант в IF). Лучшая часть этого заключается в том, что вам не нужно жестко кодировать диапазон, поскольку мы рассматриваем весь столбец.

Этот массив затем сцепляется с помощью чип-Pearsons удобной функции, которую можно найти здесь:

http://www.cpearson.com/excel/stringconcatenation.aspx

Включать код он любезно предлагает в модуль, и вы до гонок.

Answer 3

Как уже говорило PatricK, в VBA есть словари, но только через скрипты, а не так хорошо интегрированы в язык, как в Python (Бог, я скучаю по этим спискам и словарям).Этот метод обычно работает, но требует ссылки на сценарий или использование позднего связывания, как показывает PatricK.

В качестве альтернативы вы можете использовать коллекцию классов. Определите модуль класса и передайте ему некоторые переменные, один из которых - Collection. Таким образом, вы можете прокрутить свою коллекцию классов, чтобы найти букву индекса (A и B в этом примере) и извлечь список фруктов из сохраненного класса.

Я нахожу этот метод более гибким и масштабируемым (у вас есть полный контроль над модулем класса). И это «родное» решение, которое будет работать на любой машине, а также на Mac (где иногда иногда бывает больно).

Если вы хотите, я могу подробно остановиться на примере, но я никогда не смогу быть таким же полным, как Чип Пирсон на его site.