Переменная совпадение в нескольких листах

Question

В моем машинном программировании у меня есть следующий код, который отлично работал, когда у меня были все данные для машин в тех же листах, что и ComboBox2, но ТЕПЕРЬ Я реорганизовал данные и разделил их на 10 разных листов , Это означает, что один лист с элементами для каждого машинного кода.

ТЕПЕРЬ, моя проблема в этом, как мне настроить код ниже, чтобы он выполнял поиск и сопоставление в столбце AG во ВСЕХ 10 листах, а не только в текущем листе?

Я попытался использовать оператор IF и оператор Case, но они просто не сработают.

Любые советы приветствуется :)

Private Sub ComboBox2_Change() 

Dim vr% 
vr = 0 
On Error Resume Next 
vr = WorksheetFunction.Match(ComboBox2.Value, Columns("AG"), 0) 
On Error GoTo 0 
If vr = 0 Then Exit Sub 
If ComboBox2.Value = "Velg utstyr her" Then Exit Sub 
Range("AE" & vr & ":AM" & vr).Copy Destination:=Range("C91").End(xlUp).Offset(1, 0) 

End Sub  

Update 1: (Попытка Переберите листов, но не работает)

Private Sub ComboBox2_Change() 

Dim Current As Worksheet 
Dim vr% 

For Each Current In Worksheets 

vr = 0 
On Error Resume Next 
vr = WorksheetFunction.Match(ComboBox2.Value, Columns("AG"), 0) 
On Error GoTo 0 
If vr = 0 Then Exit Sub 
If ComboBox2.Value = "Velg utstyr her" Then Exit Sub 
Range("AE" & vr & ":AM" & vr).Copy Destination:=Sheets("Sheet1").Range("C91").End(xlUp).Offset(1, 0) 

Next 

End Sub 

Answer 1

Непроверенные:

Private Sub ComboBox2_Change() 

    Dim sht As Worksheet 
    Dim v 

    If ComboBox2.Value = "Velg utstyr her" Then Exit Sub 

    For Each sht In ThisWorkbook.Worksheets 

     v = Application.Match(ComboBox2.Value, sht.Range("AG:AG"), 0) 
     If Not IsError(v) Then 
      sht.range("AE" & v & ":AM" & v).Copy _ 
        Activesheet.Range("C91").End(xlUp).Offset(1, 0) 
      Exit For 'if you only expect one hit 
     End If 

    Next 

End Sub