Удалить динамически добавленные элементы управления из Userform

Question

У меня есть Excel User с динамически добавленными флажками. Добавить флажки рано с кодом, который выглядит следующим образом:

Set chkBox = Me.Controls.Add("Forms.Checkbox.1", "Checkbox" & i) 

Позже, я хочу, чтобы удалить все эти флажки. Я пытаюсь этот код:

Dim j As Integer 
'Remove all dynamically updated checkboxes 
For Each cont In Me.Controls 
    For j = 1 To NumControls 
    If cont.Name = "Checkbox" & j Then 
     Me.Controls.Remove ("Checkbox" & j) 
    End If 
    Next j 
Next cont 

Но я получаю следующее сообщение об ошибке:

любая помощь будет принята с благодарностью.

Answer 1

Лучшим подходом может быть отслеживать управление вы создаете (например, в коллекции), и использовать его чтобы удалить их.

Таким образом, ваш код не привязан к формату имени и может применяться и к другим типам управления.

Private cbxs As Collection 

Private Sub UserForm_Initialize() 
    Set cbxs = New Collection 
End Sub 

' Remove all dynamicly added Controls 
Private Sub btnRemove_Click() 
    Dim i As Long 
    Do While cbxs.Count > 0 
     Me.Controls.Remove cbxs.Item(1).Name 
     cbxs.Remove 1 
    Loop 
End Sub 


' Add some Controls, example for testing purposes 
Private Sub btnAdd_Click() 
    Dim i As Long 
    Dim chkBox As Control 
    For i = 1 To 10 
     Set chkBox = Me.Controls.Add("Forms.CheckBox.1", "SomeRandomName" & i) 
     chkBox.Top = 40 + i * 20 
     chkBox.Left = 20 
     cbxs.Add chkBox, chkBox.Name ' <-- populate tracking collection 
    Next 

    ' Demo that it works for other control types 
    For i = 1 To 10 
     Set chkBox = Me.Controls.Add("Forms.ListBox.1", "SomeOtherRandomName" & i) 
     chkBox.Top = 40 + i * 20 
     chkBox.Left = 60 
     chkBox.Add chkBox, chkBox.Name 
    Next 

End Sub 

Answer 2

Добавление проверки для управления, казалось, исправить это. Не совсем уверен, почему, но это работает.

Dim j As Integer 
'Remove all dynamically updated checkboxes 
For Each cont In Me.Controls 
    If TypeName(cont) = "CheckBox" Then 
     For j = 1 To NumControls 
      If cont.Name = "Checkbox" & j Then 
       Me.Controls.Remove cont.Name 
       Exit For 
      End If 
     Next j 
    End If 
Next cont 

Answer 3

Предполагая, что нет Othe названий элементов управления, начиная с «галочкой»,

For Each cont In Me.Controls 
    If InStr(cont.Name, "Checkbox") = 1 Then 
     Me.Controls.Remove cont.Name 
    End If 
Next cont 

Answer 4

Если вы уже знаете название элементов управления, тип и сколько, почему двойной цикл?

Обратите внимание, что элементы управления, созданные только во время выполнения, могут быть удалены.

'the following removes all controls created at runtime 
Dim i As Long 
On Error Resume Next 
With Me.Controls 
    For i = .Count - 1 to 0 step -1 
     .Remove i 
    Next i 
End With 
Err.Clear: On Error GoTo 0 

и для Вашего случая: «если все именование правильно

Dim j& 
For j = 1 To NumControls 
    Me.Controls.Remove "Checkbox" & j 
Next j 

Answer 5

я переписал оригинальный код, используя командные кнопки, а просто добавил„Me.Controls.Count“, а не„NumControls“и определенный «Конт» в качестве элемента управления. Кажется, это работает для меня. Пожалуйста, дайте мне знать, если это работает для вас:

->

On Error Resume Next 
Dim Cont As Control 
Dim C As Integer 
'Remove all dynamically updated checkboxes 
For Each Cont In Me.Controls 
    For C = 1 To Me.Controls.Count 
    If Cont.Name = "CommandButton" & C Then 
     Me.Controls.Remove ("CommandButton" & C) 
    End If 
    Next C 
Next Cont