Условное форматирование VBA

Question

Я изо всех сил пытаюсь найти элегантный способ применения условных правил форматирования через VBA. Я предпочитаю VBA, потому что: а) правила будут применяться к нескольким листам и б) он предотвращает проблему дублирования CF при копировании/вставке между рабочими листами.

У меня есть список предметов инвентаризации, которые хранятся в разных местах. Я хочу отформатировать на основе местоположения со следующим форматированием:

Цвет шрифта (изменится для каждого местоположения); Верхняя граница (тот же цвет, что и шрифт); Нижняя граница (тот же цвет, что и шрифт)

Кроме того, диапазон должен быть динамическим, чем для каждого листа, он применяется к таблице на этом листе. Я хотел бы применить один и тот же код к каждому применимому листу, вместо того, чтобы жестко закодировать имя таблицы для каждого рабочего листа.

Любая помощь была бы принята с благодарностью.

---

--UPDATE-- Я пытался адаптировать код J_V в here, но получить «ошибку времени выполнения„5“: Недопустимый вызов процедуры или аргумент» на Общественные подлодки r.FormatConditions.Add Type:=xlExpression, Formula1:=formula. Я не уверен, что последний бит на границах правильный, поскольку время выполнения останавливает макрос. Мне также нужно работать в динамических табличных ссылках, но я работаю по одной проблеме за раз.

Sub ConditionalFormatting() 

Dim myRange As Range 
Set myRange = ThisWorkbook.Sheets("Widget1").Range("Widget1_table[Location]") 

myRange.FormatConditions.Delete 

Call FormatRange(myRange, 10, "=$E5="Warehouse1") 
Call FormatRange(myRange, 11, "=$E5="Warehouse2") 
Call FormatRange(myRange, 13, "=$E5="Warehouse3") 

End Sub 

Public Sub FormatRange(r As Range, color As Integer, formula As String) 
r.FormatConditions.Add Type:=xlExpression, Formula1:=formula 
r.FormatConditions(r.FormatConditions.Count).Font.colorindex = color 

With r.FormatConditions(1).Borders(xlTop) 
    .LineStyle = xlContinuous 
    .Color = color 
    .TintAndShade = 0 
    .Weight = xlThin 
End With 
With r.FormatConditions(1).Borders(xlBottom) 
    .LineStyle = xlContinuous 
    .Color = color 
    .TintAndShade = 0 
    .Weight = xlThin 
End With 
r.FormatConditions(1).StopIfTrue = False 

End Sub 

Answer 1

Проблема на самом деле не в Sub FormatRange, но так, как вы назначаете формулу при вызове ее в Sub ConditionalFormatting. Формула содержит строку, поэтому кавычки должны быть удвоены следующим образом.

Sub ConditionalFormatting() 
    Dim myRange As Range 
    Set myRange = ThisWorkbook.Sheets("Widget1").Range("Widget1_table[Location]") 

    myRange.FormatConditions.Delete 

    Call FormatRange(myRange, 10, "=$E5=""Warehouse1""") 
    Call FormatRange(myRange, 11, "=$E5=""Warehouse2""") 
    Call FormatRange(myRange, 13, "=$E5=""Warehouse3""") 
End Sub 

Что касается второго макроса, когда вы добавляете новое условие, оно идет в нижнюю часть очереди. Если вы посмотрите на записанном выходе из создания КФ правилу вы увидите, что он обычно содержит строку,

Selection.FormatConditions(Selection.FormatConditions.Count).SetFirstPriority 

Это ставит правило CF в верхней части очереди, так что он может в дальнейшем упоминаться как .FormatConditions(1) , Если вы не хотите, чтобы он находился в верхней части очереди, вам нужно обратиться к нему как последнему в очереди, подобной этой.

Public Sub FormatRange(r As Range, clr As Integer, frml As String) 
    r.FormatConditions.Add Type:=xlExpression, Formula1:=frml 
    r.FormatConditions(r.FormatConditions.Count).Font.ColorIndex = clr 

    With r.FormatConditions(r.FormatConditions.Count).Borders(xlTop) 
     .LineStyle = xlContinuous 
     .ColorIndex = clr 
     .TintAndShade = 0 
     .Weight = xlThin 
    End With 
    With r.FormatConditions(r.FormatConditions.Count).Borders(xlBottom) 
     .LineStyle = xlContinuous 
     .ColorIndex = clr 
     .TintAndShade = 0 
     .Weight = xlThin 
    End With 
    r.FormatConditions(r.FormatConditions.Count).StopIfTrue = False 
End Sub 

Я также изменил ваш граничный .Color присвоений .ColorIndex, как 10, 11 & кажутся ColorIndex идентификаторы * зеленый, синий и фиолетовый . Гласные были удалены из ваших имен переменных, чтобы избежать конфликтов с именами свойств коллекции.