Возвращаемое значение имени файла wildcard

Question

Я попытался исследовать это вокруг interwebz, но безрезультатно.

У меня есть этот код, который ищет папку, чтобы узнать, существует ли файл. Проблема в том, что я не знаю полного имени файла, поэтому я использовал подстановочный знак. Файл с шаблоном «Provider * _extra» & «.csv» - подстановочный знак представляет собой дату и строку - например Provider_20131126_purple_extra.csv.

Я хочу знать, что это подстановочное значение - например. Я хочу назвать «20131126_purple» или что-то еще. Кто-нибудь знает, как это сделать в VBA? Заранее спасибо.

FileName = Dir$(MyPath & "PROVIDER*_EXTRA" & ".csv") 
If (Len(FileName) > 0) Then 

wb1.Sheets("Found Files").Activate 
LastRow = Range("E" & Rows.Count).End(xlUp).Row + 1 
Range("E" & LastRow).Activate 
ActiveCell = "PROVIDER EXTRA FILE" 
wb1.Sheets("Control").Activate 

Else 

End If 

Answer 1

вы можете использовать

Debug.print FileName, чтобы получить имя файла, который вы используете.

если вы хотите перебрать все файлы в папке см this

короткий образец:

Public Const PathToFolder As String = "C:\SampleFolder\" 

Sub PrintFilesNames() 
    Dim file As String 
    file = Dir$(PathToFolder) 
    While (Len(file) > 0) 
     Debug.Print file 
     file = Dir 
    Wend 
End Sub 

Answer 2

Вы можете попробовать его с помощью функции REPLACE:

wildcard = Replace(FileName, "Provider", "") 
wildcard = Replace(wildcard, "_extra.csv", "") 

Answer 3

Это будет делать то, что вы хотите.

У меня есть эта пара функций, которые я написал и использовать все время:

Function GetFilenamesMatchingPattern(ByVal pathPattern As String, _ 
    Optional attributes As VbFileAttribute = vbNormal) As String() 
    Dim i As Long 
    Dim nFiles As Long 
    Dim filenames() As String 
    nFiles = CountFilesMatchingPattern(pathPattern, attributes) 
    If nFiles > 0 Then 
     ReDim filenames(1 To nFiles) 
     filenames(1) = dir(pathPattern, attributes) 
     For i = 2 To nFiles 
      filenames(i) = dir() 
     Next i 
    Else 
     'Return unallocated array 
    End If 
    GetFilenamesMatchingPattern = filenames 
End Function 
Function CountFilesMatchingPattern(ByVal pathPattern As String, _ 
    Optional attributes As VbFileAttribute = vbNormal) As Long 
    Dim nFiles As Long 
    If dir(pathPattern, attributes) = "" Then 
     nFiles = 0 
    Else 
     nFiles = 1 
     Do While dir() <> "" 
      nFiles = nFiles + 1 
     Loop 
    End If 
    CountFilesMatchingPattern = nFiles 
End Function 

Извинения, если кто-то не нравится стиль!

Пример использование с шаблоном:

Dim filenames() As String 
filenames = GetFilenamesMatchingPattern("C:\Users\myName\Documents\Book*.xlsm") 

'returns an array of Strings: 
'{"Book1.xlsm", "Book2.xlsm", "Book2_test.xlsm"} 

Теперь для вашей конкретной проблемы, а именно получение различных подстановочных значения:

Dim i As Long 
Dim filenames() As String 
Dim wildcardValues() As String 
Dim part1 As String 
Dim part2 As String 
part1 = "Book" ' yours would be "Provider_" 
part2 = ".xlsm" ' yours would be "_extra.csv" 
filenames = GetFilenamesMatchingPattern("C:\Users\myName\Documents\" _ 
    & part1 & "*" & part2) 
ReDim wildcardValues(LBound(filenames) To UBound(filenames)) 
For i = LBound(filenames) To UBound(filenames) 
    wildcardValues(i) = Replace(Replace(filenames(i), part1, ""), part2, "") 
Next i 
'wildcardValues is now: 
'{"1", "2", "2_test"} 
'Done.