Использование findstr для многострочного И поиска

Question

Используя ниже, я смог подсчитать общее количество вхождений одного слова и получить результат, как показано ниже.

@echo off 
set "word=Windows" 
set file=log.txt 
set cnt=0 
for /f ^"eol^=^ 

delims^=^" %%a in ('"findstr /i "/c:%word%" %file%"') do set "ln=%%a"&call :countWord 

echo Server_Type Total_Users >result.txt 
echo %word%   %cnt%  >>result.txt 
exit /b 

:countWord 
setlocal enableDelayedExpansion 
:loop 
if defined ln (
set "ln2=!ln:*%word%=!" 
if "!ln2!" neq "!ln!" (
    set "ln=!ln2!" 
    set /a "cnt+=1" 
    goto :loop 
) 
) 
endlocal & set cnt=%cnt% 
exit /b 

result.txt

Server_Type Total_Users 
Windows   24 

теперь я хочу, чтобы добавить 6 новых слов, как Linux, MacOS, Andriod, Unix и т.д. .... искать в том же файле журнала и получить результат в том же формате.

, но не получить, как добиться этого, используя FINDSTR и возможно ли это с учетом ограниченной возможности RegExp Findstr? любое предложение, пожалуйста?

Answer 1

Я слегка модифицирована программу для того, чтобы преобразовать cnt переменную в array, которые имеют различные слова как индексы, например cnt[Windows]=0, cnt[Linux]=0 и т. д., поэтому :countWords подпрограмма поиска всех слов в каждой соответствующей строке. Я также удалил setlocal из подпрограммы :countWords, чтобы более точно вернуть значения массива cnt.

@echo off 
setlocal EnableDelayedExpansion 

set "words=Windows Linux MacOS Andriod Unix" 
set file=log.txt 
for %%a in (%words%) do set cnt[%%a]=0 
for /f ^"eol^=^ 

delims^=^" %%a in ('"findstr /i "%words%" %file%"') do call :countWords "%%a" 


(echo Server_Type Total_Users  
for %%a in (%words%) do (
    echo %%a   !cnt[%%a]!  
)) > result.txt 
exit /b 

:countWords 
set wordList=%words% 
:nextWord 
    for /F "tokens=1*" %%a in ("%wordList%") do (
     set word=%%a 
     set wordList=%%b 
    ) 
    set "ln=%~1" 
    :loop 
    if defined ln (
     set "ln2=!ln:*%word%=!" 
     if "!ln2!" neq "!ln!" (
     set "ln=!ln2!" 
     set /a "cnt[%word%]+=1" 
     goto :loop 
    ) 
    ) 
if defined wordList goto nextWord 
exit /b 

Answer 2

Я не пробовал это, но концепция была бы такой, как:

@echo off 
set "word=Windows Linux MacOS ..." 
set file=log.txt 
set cnt=0 
for %%i in (%word%) do (
for /f ^"eol^=^ 
... 
<the rest of your code> 
... 
) 

Answer 3

Простой способ получить отсчеты: вы просто поставить # перед именем строки поиска и увеличить значение этой новой переменной (если строка действительно то же самое) с Set /a #%%a+=1 и затем с set # вы получаете все свои счета. Очень простой и эффективный. (извините за мой страшный английский)

@ECHO OFF 

set "$file=log.txt" 
set "$Lsearch=windows unix linux macOs Android" 


for %%a in (%$LSearch%) do (set #%%a=0 
        for /f "delims=" %%* in ('type %$file% ^| findstr /i "%%a"') do if /i "%%*"=="%%a" set /a #%%a+=1) 

for /f "tokens=1,2 delims==" %%a in ('set #') do echo Server : %%a Total User : %%b