Как контролировать порядок расширения макросов схемы?

Question

Я работаю с расширением макроса Racket syntax-id-rules, что некоторые другие реализации схемы предоставляют под именем identifier-syntax. Они позволяют указывать расширения макросов, которые произойдут, даже если определенный идентификатор не находится в позиции главы. Так, например:

(define hidden #f) 
(define-syntax proxy 
    (syntax-id-rules (set!) 
    [(set! proxy v) (set! hidden v)] 
    [proxy hidden])) 

будет создан идентификатор proxy быть прокси для hidden. Это бесполезный пример, но он иллюстрирует использование.

Я нахожусь в ситуации, когда хочу глобальный обычный макрос, назовем его foo, что я хочу переопределить в некоторых случаях, когда я использую макрос идентификатора, например proxy. То есть, я хочу, чтобы иметь возможность сделать что-то вроде этого:

(define-syntax foo 
    (syntax-rules() 
    [(foo arg ...) 'default])) 

(define hidden #f) 
(define-syntax proxy 
    (syntax-id-rules (foo set!) 
    [(foo proxy arg ...) 'special] 
    [(set! proxy v) (set! hidden v)] 
    [proxy hidden])) 

(foo proxy) ; should return 'special 

Но на самом деле последняя строка возвращает 'default, потому что foo макрос получает расширен до proxy один.

Любые идеи, как я мог бы достичь чего-то в этом направлении, но с макросом идентификатора proxy, переопределяющим определение макроса по умолчанию для foo? Я не привержен этой архитектуре.

Добавлено: Это не для использования в реальном мире, а в части демонстрации теоретической точки в формальной семантике.

Answer 1

@soegaard это прекрасно. Вы не можете делать то, что хотите, без изменения макрообмена.

Чтобы продлить ответ @ soegaard, вот способ имитировать то, о чем вы просите. По сути, это макроопределение «двойной отправки». Тем не менее, как отметил соагор, вероятно, существует более идиоматический способ достичь того, чего вы хотите, в зависимости от ваших целей.

#lang racket 
(require (for-syntax syntax/parse)) 

(begin-for-syntax 
    (define (special-condition? id) 
    (and (identifier? id) 
     (regexp-match #rx"^p" ; starts with "p" 
         (symbol->string (syntax->datum id)))))) 

(define-syntax foo 
    (syntax-parser 
    [(_ special-case arg ...) 
    #:when (special-condition? #'special-case) 
    #'(special-case 'hidden-special-case-tag arg ...)] 
    ; else 
    [(_ arg ...) #''default])) 

(define hidden #f) 
(define-syntax proxy 
    (syntax-id-rules (quote set!) 
    [(proxy (quote hidden-special-case-tag) arg ...) 'special] 
    [(set! proxy v) (set! hidden v)] 
    [(proxy arg ...) 'other] 
    [proxy hidden])) 

(foo non-proxy) ; => 'default 
(foo proxy) ; => 'special 
(proxy) ; => 'other 
proxy ; => #f 
(set! proxy #t) 
proxy ; => #t 

Answer 2

Мне кажется, что вам нужно найти альтернативную стратегию. Возможно, мы сможем найти решение, если вы предоставите более подробную информацию об этой ситуации.

В любом случае, вот почему ваша стратегия не работает. Когда вы пишете

(define-syntax proxy ...) 

связывание синтаксического-трансформер с идентификатором proxy. Этот трансформатор вызывается расширителем, когда он видит либо (proxy ...), (set! proxy ...), либо proxy.

Для того, чтобы определить, что должно быть (foo proxy arg ...), уточнить его в синтаксическом трансформаторе, связанном с foo.

Теперь в зависимости от ситуации могут быть трюки, которые можно воспроизвести.

Например, можно представить, что вы завершаете свою программу в новой форме, которая переписывает (foo proxy arg ...) в (proxy 'was-a-foo-originally arg ...), а затем пусть синтаксический трансформатор для proxy обрабатывает остальные.

Удобное решение для перемещения (foo proxy arg ...) в трансформатор для foo, но вы специально запрашиваете решение, в котором foo не изменяется.