вычитая значения в одном столбце, основанные на другой колонке

Question

У меня есть входной файл следующим образом

100A 2000 
100B 150 
100C 800 
100A 1000 
100B 100 
100C 300 

Я хочу, чтобы вычесть значения в столбце 2 для каждого Uniq значения в колонке 1 поэтому из пут должен выглядеть

100A 1000 
100B 50 
100C 500 

Я попытался

awk '{if(!a[$1])a[$1]=$2; else a[$1]=$2-a[$1]}END{ for(i in a)print i" " a[i]}' file 

но из положить является:

100A 0 
100B 0 
100C 0 

пожалуйста посоветуйте

Answer 1

Так много (небольшие) вариации на та же тема.

awk ' 
    !($1 in a) {a[$1]=$2; next} 
    {a[$1]-=$2} 
    END {for (i in a) printf "%s %d\n",i,a[i]} 
' input.txt 

Уложите его как однострочный вкладыш, если хотите.

Помните, что структура awk состоит из нескольких пар condition { statement }, поэтому вы можете иногда выражать свои требования более элегантно, чем использовать if..else. (Не говоря, что это имеет место здесь - это достаточно простой awk-скрипт, который, вероятно, не имеет значения, если вы не пурист.:])

Кроме того, остерегайтесь тестирования значений так, вы сделали в состоянии в вашем if в вопросе. Обратите внимание, что в a[$1]оба параметра проверяют, является ли значение в индексе этого массива отличным от нуля. и заставляет индекс существовать с нулевым значением, если он ранее не существовал. Если вы хотите проверить наличие индекса, используйте $1 in a.

---

Обновление на основе комментариев на ваш вопрос ...

Если вы хотите вычесть последний из первого входа, игнорируя те, которые между ними, то вам необходимо держать запись ваших первых и ваших последних. Что-то вроде этого может быть достаточно.

awk ' 
    !($1 in a){a[$1]=$2;next} 
    {b[$1]=$2} 
    END {for(i in b)if(i in a)print i,a[i]-b[i]} 
' input.txt 

Обратите внимание, что, как упоминает Эд, это производит выход в случайном порядке. Если вы хотите, чтобы результат был заказан, вам понадобится дополнительный массив для отслеживания заказа. Например, это будет использовать порядок, предметы первой видели:

awk ' 
    !($1 in a) { 
    a[$1]=$2; 
    o[++n]=$1; 
    next 
    } 
    { 
    b[$1]=$2 
    } 
    END { 
    for (n=1;n<=length(o);n++) 
     print o[n],a[o[n]]-b[o[n]] 
    } 
' i 

Обратите внимание, что функция length() которая используется для определения количества элементов в массиве не является универсальным среди диалектов AWK, но он работает в обоих gawk и one-true-awk (используется во FreeBSD и др.).

Answer 2

Это AWK один лайнер делает работу:

awk '{if($1 in a)a[$1]=a[$1]-$2;else a[$1]=$2} 
     END{for(x in a) print x, a[x]}' file 

Answer 3

Вы можете использовать этот awk:

awk 'a[$1]{a[$1]=a[$1]-$2; next} {a[$1]=$2} END{for(v in a){print v, a[v]}}' file 

Answer 4

В awk.С помощью условного оператора для размещения значения/вычитание, чтобы держать его крепко:

$ awk '{ a[$1]+=($1 in a?-$2:$2) } END{ for(i in a)print i, a[i] }' file 
100A 1000 
100B 50 
100C 500 

Разъяснение:

{ 
    a[$1]+=($1 in a?-$2:$2) # if $1 in a already, subtract from it 
           # otherwise add value to it 
} 
END { 
    for(i in a)    # go thru all a 
     print i, a[i]   # and print keys and values 
} 

Answer 5

Учитывая входной сэмпл при условии, все, что вам нужно:

$ awk '$1 in a{print $1, a[$1]-$2} {a[$1]=$2}' file 
100A 1000 
100B 50 
100C 500 

Если это не все, что вам нужно, а затем предоставить более по-настоящему представительный образец ввода/вывода, который включает случаи, когда это недостаточно.