Булевы функторы в lisp

Question

Я нахожусь в ситуации, когда мне нужно объединить несколько предикатов в один. Есть ли стандартный способ сделать это, что-то похожее на compliment?

Предположим, что существует несколько простых предикатов (например is-fruit-p, is-red-p, grows-on-trees-p и т.д.), а также список объектов, из которых подмножество должны быть отфильтрованы с использованием более одного предиката. Какой лучший способ добиться этого, чем следующее:

(remove-if #'is-fruit-p 
      (remove-if #'is-red-p 
         (remove-if #'grows-on-trees-p list-of-objects))) 

Answer 1

Я не уверен, что такая функция доступна из коробки. Если вам нужно объединить функции, которые вы можете определить во время компиляции, вы можете написать макрос для этого. Если вам нужно динамически обнаруживать функции предикатов, вы можете написать функцию для этого, которая будет зацикливать список функций и накапливать результаты до ложного состояния.

Макрос может выглядеть следующим образом:

(defmacro combine-predicates (combine-func &rest preds) 
    (let ((x (gensym))) 
    `(lambda (,x) (,combine-func ,@(loop for p in preds 
         collecting `(funcall ,p ,x)))))) 

И вы можете использовать его как этот

(remove-if (combine-predicates and 
           #'is-fruit-p 
           #'is-red-p 
           #'grows-on-trees-p) obj-list) 

Answer 2

(let ((predicates '(zerop evenp))) 
    (remove-if (lambda (item) 
       (some (lambda (fn) (funcall fn item)) 
        predicates)) 
      '(0 1 2 3 4 0 1 2 3 4))) 

Answer 3

Вы уверены, что специальный синтаксис действительно поможет? Рассмотрим следующий

(lambda (x) 
    (and (is-fruit-p x) 
     (or (grows-on-tree-p x) 
      (is-red-p x)))) 

и теперь чуть более общий

(lambda (x) 
    (and (is-fruit-p x) 
     (or (grows-on-tree-p x) 
      (eq (color x) 'red)))) 

или

(lambda (x) 
    (and (is-fruit-p x) 
     (or (grows-on-tree-p x) 
      (eq (color x) desired-color)))) ; desired-color captured lexical 

Даже если вы строите специальный синтаксис для предикаты вы думаете, добавленная сложность языка стоит жесткость, которую вы получите? Например, вы собираетесь определить предикат #'weights-exactly-five-ounces-p? Как насчет #'weights-up-to-and-including-six-and-half-ounces-p?

Если вы начинаете нуждаться в параметрическом предикате и используете для этого лямбда-формы, то с помощью комбайнера вы будете писать больше кода, чем не использовать его, потому что для каждого параметрического термина потребуется оболочка (lambda (x) ...). Что еще более важно, что код будет также сложнее читать (в дополнение к необходимости изучения специального нового макроса для комбинации предикатов).

ИМО может иметь смысл писать и/или комбинаторы, если вы переданы в предикаты, и вам нужно передать предикаты кому-то еще ... но не для написания кода, который вы использовали в примере; для этого я бы написать

(remove-if (lambda (x) (or (is-fruit-p x) 
          (is-red-p x) 
          (grows-on-trees-p x))) 
      list-of-objects) 

Меньше писать, меньше читать, ничего лишнего, чтобы узнать, тривиальное параметризовать.

Предположим, например, что вы хотите список фруктов того же цвета, что и у вас (в mine) и с таким же весом или, возможно, более тяжелым ...

(remove-if-not (lambda (x) (and (is-fruit-p x) 
           (eq (color x) (color mine)) 
           (>= (weight x) (weight mine)))) 
       objects) 

Answer 4

Подход с использованием первого класса функций:

(defun complement (func) 
    (lambda (x) (not (funcall func x)))) 

(defun conjoin (pred1 pred2) 
    (lambda (x) (and (funcall pred1 x) (funcall pred2 x)))) 

(defun disjoin (pred1 pred2) 
    (lambda (x) (or (funcall pred1 x) (funcall pred2 x)))) 

Из которого вы можете производить

(remove-if (conjoin #'is-fruit-p (conjoin #'is-red-p #'grows-on-trees-p)) list-of-objects) 

Answer 5

функции высшего порядка, как disjoin и conjoin доступны в quicklisp устанавливаемым alexandria библиотеки.

CL-USER> (ql:quickload "alexandria") 
... 
CL-USER> (remove-if (alexandria:disjoin #'zerop #'oddp #'minusp) 
        '(0 -1 1 -2 2)) 
=> (2)