Джеба много удовольствия, но это очень сильно зависит от длины текста, который добавляется или удаляется. Я думаю, что контр-интуитивные результаты - это то, что означало подпора, когда он сказал: «Если вы измените его до этого, он начнет делать странные вещи (повторяя команды и т. Д.)».
Я изменил код jeb, чтобы показать, как динамический код переменной длины может быть свободно изменен в начале исполняемого командного файла до тех пор, пока выполняется соответствующее заполнение. Вся динамическая секция полностью заменяется каждой итерацией. Каждая динамическая строка имеет префикс без помех ;. Это удобно разрешать FOR /F, чтобы удалить динамический код из-за неявного параметра EOL=;.
Вместо поиска определенного номера строки, я ищу конкретный комментарий, чтобы найти, где начинается динамический код. Это проще в обслуживании.
Я использую линии равных знаков, чтобы безвредно использовать код для расширения и сжатия. Может использоваться любая комбинация следующих символов: запятая, точка с запятой, равная, пробел, табуляция и/или новая строка. (Конечно, отступы не могут начинаться с точки с запятой.) Знаки равенства в круглых скобках допускают расширение кода. Знаки равенства после круглых скобок допускают сокращение кода.
Отметьте, что FOR /F полоски пустые линии.Это ограничение можно преодолеть, используя FINDSTR, чтобы префикс каждой строки с номером строки, а затем разделил префикс в цикле. Но дополнительный код замедляет работу, поэтому делать это не стоит, если код не зависит от пустых строк.
@echo off
setlocal DisableDelayedExpansion
echo The starting filesize is %~z0
:loop
echo ----------------------
::*** Start of dynamic code ***
;set value=1
::*** End of dynamic code ***
echo The current value=%value%
::
::The 2 lines of equal signs amount to 164 bytes, including end of line chars.
::Putting the lines both within and after the parentheses allows for expansion
::or contraction by up to 164 bytes within the dynamic section of code.
(
call :changeBatch
==============================================================================
==============================================================================
)
================================================================================
================================================================================
set /p "quit=Enter Q to quit, anything else to continue: "
if /i "%quit%"=="Q" exit /b
goto :loop
:changeBatch
(
for /f "usebackq delims=" %%a in ("%~f0") do (
echo %%a
if "%%a"=="::*** Start of dynamic code ***" (
setlocal enableDelayedExpansion
set /a newValue=value+1, extra=!random!%%9
echo ;set value=!newValue!
for /l %%n in (1 1 !extra!) do echo ;echo extra line %%n
endlocal
)
)
) >"%~f0.tmp"
::
::The 2 lines of equal signs amount to 164 bytes, including end of line chars.
::Putting the lines both within and after the parentheses allows for expansion
::or contraction by up to 164 bytes within the dynamic section of code.
(
move /y "%~f0.tmp" "%~f0" > nul
==============================================================================
==============================================================================
)
================================================================================
================================================================================
echo The new filesize is %~z0
exit /b
Вышеуказанные работы, но все гораздо проще, если динамический код перемещается в подпрограмму в конце файла. Код может расширяться и сокращаться без ограничений и без необходимости заполнения. FINDSTR намного быстрее, чем FOR/F при удалении динамической части. Динамические линии можно безопасно префикс с точкой с запятой (включая метки!). Затем опция FINDSTR/V используется для исключения строк, начинающихся с точки с запятой, и новый динамический код можно просто добавить.
@echo off
setlocal DisableDelayedExpansion
echo The starting filesize is %~z0
:loop
echo ----------------------
call :dynamicCode1
call :dynamicCode2
echo The current value=%value%
call :changeBatch
set /p "quit=Enter Q to quit, anything else to continue: "
if /i "%quit%"=="Q" exit /b
goto :loop
:changeBatch
(
findstr /v "^;" "%~f0"
setlocal enableDelayedExpansion
set /a newValue=value+1, extra=!random!%%9
echo ;:dynamicCode1
echo ;set value=!newValue!
echo ;exit /b
echo ;
echo ;:dynamicCode2
for /l %%n in (1 1 !extra!) do echo ;echo extra line %%n
echo ;exit /b
endlocal
) >"%~f0.tmp"
move /y "%~f0.tmp" "%~f0" > nul
echo The new filesize is %~z0
exit /b
;:dynamicCode1
;set value=33
;exit /b
;
;:dynamicCode2
;echo extra line 1
;exit /b
Вы должны любить так быстро ответы. Вы уже запустили пакет> опубликованный вопрос> получили ответ> отредактировали файл до завершения выполнения! –
Также обратите внимание, что когда пакетный файл удаляется или переименовывается, момент, когда текущая команда завершила ошибку, будет выдана: «Пакетный файл не может быть найден». –