Количество вхождений символа в строке (командный файл)

Question

Мне нужно создать командный файл в окнах для анализа всех имен файлов, доступных в папке, и переместить файлы, соответствующие некоторым условиям, в папку. Я уже создал цикл цикла с помощью команды FOR, и я установил имя файла для переменной. Теперь мне нужно проверить, сколько «-» символов hypen находятся в переменной имени файла; если вхождения этого символа больше 10, файл не должен перемещаться. Кроме того, мне нужно также проверить, есть ли место внутри имени файла: также в этом случае файл не может быть перемещен. Просьба: каким образом я могу создать скрипт для проверки числа вхождений hypen в переменной и наличия символа пробела?

Большое спасибо

Answer 1

Простой метод определения количества переносов, содержащихся в строке будет сравнить длину исходной строки с длиной строки с дефисом удалены: число дефисов разница в длине.

1. Save the length of the original string 
2. Remove all hyphens from the string 
3. Compare the length of the new string to that of the original: 
     originalLength - newLength = numberOfHyphens 

Аналогичным образом этот метод может использоваться для определения наличия пространства. Если длина исходной строки больше длины строки минус пробелы, то пространство должно быть удалено и, следовательно, должно существовать в исходной строке.

Answer 2

Если я вас правильно понял, вы действительно не хотите, чтобы узнать, сколько hypens имя есть, но просто знать, если имя более 10 hypens. Это может быть легко достигнуто с помощью "tokens=12 delims=-" опции for /F команды:

EDIT: Измененный код соответственно нового запроса заявил в комментарии. Новый код проверяет, содержит ли имя ровно 10 hypens и не включает пробел.

@echo off 
setlocal 

for %%a in (one-two-three-four-five-six-seven-eight-nine-end.txt 
      one-two-three-four-five-six-seven-eight-nine-ten-end.txt 
      one-two-three-four-five-six--eight-nine-ten-end.txt 
      one-two-three-four-five---eight-nine-ten-end.txt 
      one-two-three-four-five----nine-ten-end.txt 
      one-two-three-four-five-----ten-end.txt 
      one----------end.txt 
      ----------.txt 
      one-two-three-four-five-six-seven-eight-nine-ten-eleven-end.txt 
      "one-two-three-four-five-SIX SEVEN--eight-nine-ten-end.txt") do (
    set "fileName=%%~a" 
    call :checkName 
) 
goto :EOF 


:checkName 
echo Checking "%fileName%" 
set "result=Don't have 10 hypens" 
for /F "tokens=11,12 delims=-" %%a in ("%filename:--=X-X-X%") do (
    if "%%a" neq "" if "%%b" equ "" set "result=Name correct" 
) 
for /F "tokens=2" %%a in ("%fileName%") do if "%%a" neq "" set "result=Include space" 
echo %result% 
exit /B 

Answer 3

Этот код использует только for /f Tokenizer, чтобы определить, является ли файл должен быть скопирован или исключены. В случае hypen, 10 - символов генерируют 11 токенов, более или менее является причиной исключения. В случае пространства одно пространство генерирует два токена. Это простая часть, но

• В пробеге hypen может присутствовать, а for /f токенизатор обрабатывает последовательные разделители, как только один разделитель, каждый hypen заменяется -# и имя файла с префиксом # для обеспечения правильный раскол.

• Чтобы выполнить замену строки, нам нужна нормальная переменная, а не сменный параметр for. Итак, нам нужно отсроченное расширение, чтобы читать содержимое измененной переменной. Но, с задержкой расширения активно, символы ! становятся проблемой, поскольку синтаксический анализатор попытается интерпретировать его как ссылку на переменную. Чтобы избежать этого, отсроченное расширение включается только в случае необходимости и снова отключается.

• Чтобы обрабатывать разделение пространства, имя файла имеет префикс и суффикс #, чтобы гарантировать, что начальное или конечное пространство правильно обработано.

@echo off 
    setlocal enableextensions disabledelayedexpansion 

    rem Generate a set of test files 
    type nul > "0-1-2-3-4-5-6-7-8-9-10-11-12.testFile" 
    type nul > "0-1-2-3-4-5-6-7-8-9-10-11.testFile" 
    type nul > "0-1-2-3-4-5-6-7-8-9-10.testFile" 
    type nul > "0-1-2-3-4-5-6 -7-8-9-10.testFile" 
    type nul > "0-1-2-3-4-5-6-7-8-9.testFile" 
    type nul > "-----------.testFile" 
    type nul > "----------.testFile" 
    type nul > "!-----------!.testFile" 
    type nul > "!----------!.testFile" 
    type nul > "noSpaces.testFile" 
    type nul > "this file has spaces.testFile" 

    type nul > "0-1-2-3-4-5!!-6-!!7-8-9-10-11-12.testFile" 
    type nul > "0-1-2-3-4-5!!-6-!!7-8-9-10-11.testFile" 
    type nul > "0-1-2-3!!-4-5-6-7-8-9!!-10.testFile" 
    type nul > "0-1-2-3!!-4-5-6-7-8!-!9.testFile" 
    type nul > "no!Sp!aces.testFile" 
    type nul > "this !file! has spaces.testFile" 


    for %%f in (*) do (
     rem The default behaviour is not to exclude the file 
     set "exclude=" 

     rem Test the hypen conditions 
     set "fileName=%%~nf" 
     setlocal enabledelayedexpansion 
     for /f "tokens=1,11,12 delims=-" %%a in ("#!fileName:-=-#!") do (
      endlocal 
      rem Testing less than 10 hypen 
      if "%%~b"=="" set "exclude=1" 
      rem Testing more than 10 hypen 
      if not "%%~c"=="" set "exclude=1" 
     ) 

     rem Test if the file name contains a space 
     for /f "tokens=1,2" %%a in ("#%%~nf#") do if not "%%~b"=="" set "exclude=1" 

     rem Now we know what to do with the file 
     if defined exclude (
      echo EXCLUDE "%%~ff" 
     ) else (
      echo COPY "%%~ff" 
     ) 
    ) 

    del /q "*.testFile" 

Другой способ сделать это, чтобы отфильтровать список файлов, извлекать только те, которые должны быть обработаны

for /f "delims=" %%a in (' 
    dir /b 
    ^| findstr /v /c:" " 
    ^| findstr /r /x /c:"[^-]*-[^-]*-[^-]*-[^-]*-[^-]*-[^-]*-[^-]*-[^-]*-[^-]*-[^-]*-[^-]*" 
') do echo COPY %%~fa