Cypher Count возвращает null вместо 0

Question

Как мне сделать это с нулевым значением? Каждый раз, когда ANY из полей, которые я хочу вернуть, равно нулю, весь запрос возвращает null? Я продолжаю сталкиваться с этой проблемой, и мне отчаянно нужно решение.

START bp=node({startnodeid}) 
WITH bp 
MATCH (bp)<-[r1?:VIEWED_PROFILE]-() 
WHERE r1.timestamp > {weekStart} AND r1.timestamp < {firstDay} 
WITH count(r1) AS dayOne, bp 
MATCH (bp)<-[r2?:VIEWED_PROFILE]-() 
WHERE r2.timestamp > {firstDay} AND r2.timestamp < {secondDay} 
WITH count(r2) AS dayTwo, dayOne, bp 
MATCH (bp)<-[r3?:VIEWED_PROFILE]-() 
WHERE r3.timestamp > {secondDay} AND r3.timestamp < {thirdDay} 
WITH count(r3) AS dayThree, dayTwo, dayOne, bp 
MATCH (bp)<-[r4?:VIEWED_PROFILE]-() 
WHERE r4.timestamp > {thirdDay} AND r4.timestamp < {fourthDay} 
WITH count(r4) AS dayFour, dayThree, dayTwo, dayOne, bp 
MATCH (bp)<-[r5?:VIEWED_PROFILE]-() 
WHERE r5.timestamp > {fourthDay} AND r5.timestamp < {fifthDay} 
WITH count(r5) AS dayFive, dayFour, dayThree, dayTwo, dayOne, bp 
MATCH (bp)<-[r6?:VIEWED_PROFILE]-() 
WHERE r6.timestamp > {fifthDay} AND r6.timestamp < {sixthDay} 
WITH count(r6) AS daySix, dayFive, dayFour, dayThree, dayTwo, dayOne, bp 
MATCH (bp)<-[r7?:VIEWED_PROFILE]-() 
WHERE r7.timestamp > {sixthDay} AND r7.timestamp < {seventhDay} 
RETURN count(r7) AS daySeven, daySix, dayFive, dayFour, dayThree, dayTwo, dayOne 

Мне нужны анкеты для просмотра за предыдущие семь дней по статистическим соображениям.

Neo консоль: http://console.neo4j.org/?id=cy5v5k

В этой консоли, например, метки времени, нечетные числа, где мои параметры были следующими:

weekStart = 0; 
firstDay = 2; 
secondDay = 4; 
thirdDay = 6; 
fourthDay = 8; 
fifthDay = 10; 
sixthDay = 12; 
seventhDay = 14; 

и мои ожидаемые возвращаемые значения были следующими:

dayOne = 1; 
dayTwo = 3; 
dayThree = 2; 
dayFour = 1; 
dayFive = 1; 
daySix = 4; 
daySeven = 0; 

Answer 1

Вы используете 2.0? Если это так, вы, вероятно, должны полностью реорганизовать этот запрос, чтобы использовать CASE/WHEN и разрывать свои дни недели там, вместо отдельных статей WITH. http://console.neo4j.org/r/utsrzy

MATCH (n)-[r:VIEWED_PROFILE]->(p) 
RETURN sum(CASE WHEN r.timestamp > 0 AND r.timestamp < 2 THEN 1 ELSE 0 END) AS day1, 
     sum(CASE WHEN r.timestamp > 2 AND r.timestamp < 4 THEN 1 ELSE 0 END) AS day2, 
     sum(CASE WHEN r.timestamp > 4 AND r.timestamp < 6 THEN 1 ELSE 0 END) AS day3, 
     sum(CASE WHEN r.timestamp > 6 AND r.timestamp < 8 THEN 1 ELSE 0 END) AS day4, 
     sum(CASE WHEN r.timestamp > 8 AND r.timestamp < 10 THEN 1 ELSE 0 END) AS day5, 
     sum(CASE WHEN r.timestamp > 10 AND r.timestamp < 12 THEN 1 ELSE 0 END) AS day6, 
     sum(CASE WHEN r.timestamp > 12 AND r.timestamp < 14 THEN 1 ELSE 0 END) AS day7 

Если вы используете 1.9, вместо count(r7) и т.д., сделать count(1).

Обновление, что быстрое исправление не работает для 1.9. Вот немного манипуляций коллекции, чтобы получить 1.9, чтобы сделать это для вас:

http://console.neo4j.org/r/cata9u

START bp=node(1) 
MATCH (bp)<-[r1?:VIEWED_PROFILE]-() 
WITH collect(r1.timestamp) AS times 
RETURN length(filter(t IN times WHERE t > 0 AND t < 2)) AS day1, 
     length(filter(t IN times WHERE t > 2 AND t < 4)) AS day2, 
     length(filter(t IN times WHERE t > 12 AND t < 14)) AS day7