Доступ к свойствам в подклассе HashMap

Question

У меня есть следующий класс, который является подклассом HashMap и имеет геттеры и сеттеры для некоторых записей на карте.

Обратите внимание: Этот класс исходит из основы я использую, так что я не могу изменить его

class Mapish extends HashMap { 
    static final PROPERTY_KEY = 'PROP' 

    def getProperty() { 
    get(PROPERTY_KEY) 
    } 

    def setProperty(def value) { 
    put(PROPERTY_KEY, value) 
    } 
} 

Можно ли отключить Карта собственности нотации в Groovy для этого класса, так что свойство доступ вызовет геттер? Иными словами, чтобы пройти следующее?

def m = new Mapish() 
m.setProperty('value') 

assert m.property == 'value' // same as m.getProperty() 

и следующий будет бросать groovy.lang.MissingPropertyException

m.PROP 

Answer 1

После длительного сеанса отладки я обнаружил, что MetaClassImpl имеет свойство isMap. В случае, если данный класс назначается Map, это true. Эта переменная заставляет класс иметь синтаксический синтаксический синтаксический синтаксис, поэтому, если он установлен в false, экземпляры класса не будут вести себя как Карты. Единственная загвоздка в том, что поле final, поэтому отражение необходимо, чтобы установить его в false

import java.lang.reflect.Field 
import java.lang.reflect.Modifier 

class Mapish extends HashMap { 
    static final PROPERTY_KEY = 'PROP' 

    def getProperty() { 
    get(PROPERTY_KEY) 
    } 

    def setProperty(def value) { 
    put(PROPERTY_KEY, value) 
    } 

} 

// this method does basically this: c.metaClass.delegate.@isMap = false 
// but since isMap is final the assignment throws exception 
def unmapify(Class c) { 
    def meta = c.metaClass.delegate 
    def isMapField = meta.class.getDeclaredField("isMap") 
    def modifiersField = Field.getDeclaredField("modifiers") 
    modifiersField.accessible = true 
    modifiersField.setInt(isMapField, isMapField.getModifiers() & ~Modifier.FINAL) 

    isMapField.accessible = true 
    isMapField.set(meta, false) 
} 

unmapify(Mapish) 

def m = new Mapish() 
m.setProperty('value') 

assert m.property == 'value' 

try { 
    m.PROP 
    assert false 
} catch (ignore) {} 

Answer 2

Я не знаю, как сделать карты не ведут себя как Карты в Groovy. Возможно, вам следует рассмотреть вопрос о том, чтобы не распространять HashMap. Нечто подобное даст вам поведение, которое вы ищете:

class Mapish { 
    static final PROPERTY_KEY = 'PROP' 
    private map = [:] 
    private getMap() { throw new groovy.lang.MissingPropertyException() } 
    private void setMap(def map) { throw new groovy.lang.MissingPropertyException() } 

    def getProperty() { 
    map[PROPERTY_KEY] 
    } 

    def setProperty(def value) { 
    map[PROPERTY_KEY] = value 
    } 
} 

Тогда я бы ожидать, что ваши образцы кода, чтобы вести себя так, как вы хотите.

Answer 3

Я считаю, что meta-programming может помочь здесь.

Рассмотрим следующий пример:

// original 

class Mapish extends HashMap { 
    static final PROPERTY_KEY = 'PROP' 

    def getProperty() { 
     get(PROPERTY_KEY) 
    } 

    def setProperty(def value) { 
     put(PROPERTY_KEY, value) 
    } 
} 

// meta-programming augmentation 

Mapish.metaClass.getProperty { String arg -> 
    if (arg == "property") { 
     delegate.getProperty() 
    } else { 
     throw new MissingPropertyException("illegal property: " + arg) 
    } 
} 

// test 

def m = new Mapish() 

m.setProperty("foo") 
assert "foo" == m.property 

try { 
    m.PROP 
    throw IllegalStateException("should not get here") 
} catch (MissingPropertyException ex) { 
    // println "caught exception as expected" 
}