Эффективный способ определения даты окончания недели без таблицы календаря

Question

Я использую приведенный ниже код SQL в MS SSMS, чтобы найти дату окончания недели. Мне часто приходится переключаться между средой и воскресенью как день окончания недели. Боковое замечание, мои наборы данных часто находятся в 100 000.

Есть ли более эффективный способ сделать это, чем то, что у меня ниже, чем использование таблицы календаря?

/* Declare Variables */ 
DECLARE @WeekendingDay VARCHAR(10); 
DECLARE @DayNumber INT; 
DECLARE @InputDate VARCHAR(10); 
DECLARE @conInputDate DATETIME; 
DECLARE @outWeekending DATETIME; 
DECLARE @CovertToInt VARCHAR(10); 

/* --------------------Inputs-------------------- */ 

/* uncomment the weekending day you want */ 
--Set @WeekendingDay = 'Monday' 
--Set @WeekendingDay = 'Tuesday' 
--Set @WeekendingDay = 'Wednesday' 
--Set @WeekendingDay = 'Thursday' 
--Set @WeekendingDay = 'Friday' 
--Set @WeekendingDay = 'Saturday' 
SET @WeekendingDay = 'Sunday'; 

/* Date you want the weekending of */    
SET @InputDate = '29/12/2016'; 

/* --------------------Process-------------------- */ 
SET @DayNumber = CASE @WeekendingDay 
        WHEN 'Sunday' THEN 1 
        WHEN 'Monday' THEN 2 
        WHEN 'Tuesday' THEN 3 
        WHEN 'Wednesday' THEN 4 
        WHEN 'Thursday' THEN 5 
        WHEN 'Friday' THEN 6 
        WHEN 'Saturday' THEN 7 
       END; 


SET @conInputDate = CONVERT(DATETIME, @InputDate, 103); 
SET @outWeekending = DATEADD(dd, 
          CASE WHEN DATEPART(DW, @conInputDate) = @DayNumber 
            THEN 0 
            ELSE -1 * DATEPART(DW, @conInputDate) + 7 
             + @DayNumber 
          END, @conInputDate); 

/* --------------------Output-------------------- */ 
PRINT @outWeekending; 

Answer 1

Это даст вам понедельник недели. В зависимости от того, в какой день вы хотите использовать в качестве конца, вы можете отрегулировать его по мере необходимости.

DECLARE @date DATETIME = GETUTCDATE()-5 

SELECT 
    @date 
    ,DATEADD(WEEK, DATEDIFF(WEEK, 0, @date),0) --Monday 
    ,DATEADD(DD,1,DATEADD(WEEK, DATEDIFF(WEEK, 0, @date),0)) --Tuesday 
    ,DATEADD(DD,2,DATEADD(WEEK, DATEDIFF(WEEK, 0, @date),0)) --Wednesday 
    ,DATEADD(DD,3,DATEADD(WEEK, DATEDIFF(WEEK, 0, @date),0)) --Thursday 
    ,DATEADD(DD,4,DATEADD(WEEK, DATEDIFF(WEEK, 0, @date),0)) --Friday 
    ,DATEADD(DD,5,DATEADD(WEEK, DATEDIFF(WEEK, 0, @date),0)) --Saturday 
    ,DATEADD(DD,6,DATEADD(WEEK, DATEDIFF(WEEK, 0, @date),0)) --Sunday