Добавление пользовательского интерфейса в пакетную программу

У меня есть этот код.Добавление пользовательского интерфейса в пакетную программу

@ECHO OFF 
    :Values 
    SET strSSID= 
    SET strPWD= 
    ECHO Please enter the ssid: 
    SET /p strSSID=SSID: 
    ECHO. 
    ECHO Please enter the password: 
    SET /p strPWD=Password: 

    IF ".%strSSID%"=="." GOTO :TryAgain 
    IF ".%strPWD%"=="." GOTO :TryAgain 

    CALL :HostedNW "%strSSID%" "%strPWD%" 
    pause 
    GOTO :EOF 
    :HostedNW 
    ECHO 
    C:\Windows\System32\netsh.exe wlan set hostednetwor mode=allow ssid="%~1" key="%~2" keyUsage=persistent 
    SET strSSID= 
    SET strPWD= 
    GOTO :EOF 
    :TryAgain 
    CLS 
    ECHO. 
    ECHO One or more inputs weren't correct. 
    ECHO Please try again. 
    ECHO. 
    GOTO :Values

В котором я принял соответствующие входные сигналы от пользователя, как SSID и пароль, теперь у меня есть второй код, как:

C:\Windows\System32\netsh.exe wlan start hostednetwork

Этот код включит WiFi, а другой код, который:

C:\Windows\System32\netsh.exe wlan stop hostednetwork

Этот код отключит WiFi. Теперь я хочу, чтобы все эти коды были в одном формате для трекинга и хотели отобразить надлежащий пользовательский интерфейс, в котором: кнопка с первым нажатием будет показывать «Configure WiFi» секундная кнопка будет отображаться «Включить» Третья кнопка клика показывает «Turn Off " кнопка с четвертым нажатием кнопки выйдет из пользовательского интерфейса.

и соответствующие кнопки будут запускать соответствующий код, предназначенный для него, таким же образом, как указано выше. Если возможно, подскажите, как улучшить пользовательский интерфейс этого файла. Пожалуйста, помогите мне с этой проблемой. , ,

источник

2014-11-09 SwaPnil Magar

Пакет является текстовым, что означает, что он не способен сделать что-либо доступным для клика. – SomethingDark

Хорошо, я понял. Но можно ли создать файл, в котором отображаются 4 параметра и запрашивается конкретное –

. Вы можете делать текстовые меню, конечно. Вы можете использовать команду 'choice', если вы используете систему позже XP, или' set/p', а некоторые - в противном случае. – SomethingDark

Надеюсь, это нечто похожее на то, что вы ищете.

@echo off 

:mainmenu 
cls 
echo ********************* 
echo *  WiFi Menu  * 
echo ********************* 
echo * 1. Configure WiFi * 
echo * 2. Enable WiFi * 
echo * 3. Disable WiFi * 
echo * 4. Quit   * 
echo ********************* 
choice /C:1234 >nul 

if %errorlevel% equ 1 goto config 
if %errorlevel% equ 2 goto enable 
if %errorlevel% equ 3 goto disable 
if %errorlevel% equ 4 goto quit 

:quit 
exit /b 

:config 
set "strSSID=" 
set "strPWD=" 

:: Enter the SSID and password 
set /p "strSSID=Please enter the SSID: " 
set /p "strpwd=Please enter the password: " 

:: Ensure that the user input is not empty 
if "%strSSID%"=="" goto tryagain 
if "%strPWD%"=="" goto tryagain 

:: Affiliate the SSID with the password 
netsh wlan set hostednetwork mode=allow ssid="%strSSID%" key="%strPWD%" keyUsage=persistent 
echo Wifi configured 
pause 
goto mainmenu 

:: Inform the user that required information was not supplied 
:tryagain 
cls 
echo. 
echo Please input both an SSID and password. 
echo. 
goto config 

:: Activate the WiFi 
:enable 
netsh wlan start hostednetwork 
echo WiFi enabled 
pause 
goto mainmenu 

:: Disable the WiFi 
:disable 
netsh wlan stop hostednetwork 
echo WiFi disabled 
pause 
goto mainmenu

источник

2014-11-09 08:27:05 SomethingDark

Спасибо, сэр за вашу полезную помощь. –

Добавление пользовательского интерфейса в пакетную программу

ответ

Смежные вопросы