Как получить все возможные комбинации соседних элементов в следующем порядке с помощью Perl?

Question

Например, у меня есть массив

my @arr = qw(0 1 2 3 4); 

Как получить следующие комбинации:

0 
01 
012 


1 
12 
123 
1234 
2 
23 
234 
3 
34 
4 

Если какой-либо, что название для такого рода комбинации (или перестановки)?

Спасибо, как всегда!

Answer 1

Использование массива ломтиков:

#! /usr/bin/perl 

use warnings; 
use strict; 

my @arr = qw(0 1 2 3 4); 

my @result; 
for (my $i = 0; $i < @arr; $i++) { 
    for (my $j = $i; $j < @arr; $j++) { 
    push @result => [ @arr[$i .. $j] ]; 
    } 
} 

print @$_, "\n" for @result; 

Выход:

0 
01 
012 


1 
12 
123 
1234 
2 
23 
234 
3 
34 
4

Answer 2

Лично я считаю "стиль C" для цикла, который gbacon использует часто усложняет код без необходимости. И, как правило, можно заменить его на «диапазон-стиль» для цикла, который проще отслеживать.

#!/usr/bin/perl 

use strict; 
use warnings; 

my @arr = qw(0 1 2 3 4); 

my @result; 
for my $i (0 .. $#arr) { 
    for my $j ($i .. $#arr) { 
    push @result => [ @arr[$i .. $j] ]; 
    } 
} 

print @$_, "\n" for @result; 

Answer 3

Вот способ разделить проблему на более дискретные компоненты:

use strict; 
use warnings; 

sub consec_subseq_leading { 
    # (1, 2, 3) ==> ([1], [1, 2], [1, 2, 3]) 
    return map [ @_[0 .. $_] ], 0 .. $#_; 
} 

sub consec_subseq { 
    # (1, 2, 3) ==> (F(1, 2, 3), F(2, 3), F(3)) 
    # where F = consec_subseq_leading 
    my $j = $#_; 
    return map consec_subseq_leading(@_[$_ .. $j]), 0 .. $j; 
} 

my @cs = consec_subseq(0 .. 4); 
print "@$_\n" for @cs;