Объединить 1 поле из нескольких строк с помощью AmpScript

Question

У меня есть расширение данных, содержащие строки и столбцы, такие как:

emailAddress  orderNumber firstName lastName customerOrder 
cust1@gmail.com 1111   Bill  Adams  2 brown shoes 
cust1@gmail.com 1111   Bill  Adams  2 green socks 
cust1@gmail.com 1111   Bill  Adams  1 orange backpack 
cust1@gmail.com 2222   Bill  Adams  2 pink gloves 
cust2@gmail.com 3333   David  Sherwood 5 yellow hats 

То, что я пытаюсь сделать, это создать заказ получил электронную почту от этих данных, предпочтительно не изменяя его из источника. Поэтому в идеале выход электронной почты будет группировать customerOrder для каждого клиента, основываясь на номере orderNumber. Затем CustomerOrder объединяется и вставляется в сообщение электронной почты (обратите внимание, что это упрощено совсем немного, CustomerOrder на самом деле является HTML для вставки в HTML-таблицу в электронном письме).

До сих пор я был в состоянии сделать это гораздо очень простой ход:

%%[ 
Set @customerOrder = 
LookupOrderedRows("transactionsList", 
"0", 
"customerOrder", 
"orderNumber", 
"1111") 
]%% 

С помощью этого кода я вижу, что у меня есть 3 записей для номера заказа 1111. Но теперь я застрял. Нужно ли создавать цикл if/then? Или есть способ извлечь результат из функции LookupOrderedRows и проанализировать ее для использования в таблице HTML в электронном письме?

Answer 1

Используя один из lookup examples на моем блоге, вы можете сделать что-то вроде этого:

%%[ 
var @rows, @row, @rowCount, @numRowsToReturn, @emailAddress, @i, @prevOrderNumber 

set @emailAddress = AttributeValue("emailaddr") 
set @numRowsToReturn = 0 /* 0 means all */ 
set @rows = LookupOrderedRows("transactionsList", @numRowsToReturn, "orderNumber", "emailAddress", @emailAddress) 

set @rowCount = rowcount(@rows) 

if @rowCount > 0 then 

    set @prevOrderNumber = "" 

    for @i = 1 to @rowCount do 

     var @orderNumber, @firstName, @lastName, @customerOrder 
     set @row = row(@rows,@i) /* get row based on loop counter */ 

     set @orderNumber = field(@row,"orderNumber") 
     set @firstName = field(@row,"firstName") 
     set @lastName = field(@row,"lastName") 
     set @customerOrder = field(@row,"customerOrder") 

     /* output headings for first order or when order # changes */ 
     if empty(@prevOrderNumber) or @prevOrderNumber != @orderNumber then 
      outputline(concat("<br>Order #:", @orderNumber)) 
      outputline(concat("<br>Name: ", @firstName, " ", @lastName)) 
      outputline(concat("<br>Line items:<br>")) 
      set @prevOrderNumber = @orderNumber 
     endif 

     outputline(concat("<br>",@customerOrder)) 

    next @i 

else 

    outputline(concat("<br>No transactionsList rows found")) 

endif 
]%%