Выберите из таблицы Access, где ID является строкой

Question

Я код в Excel, который обновляет таблицу доступа, основанную на RTP_ID если равен IngID, следующие матчи и работы, если они являются числовыми в RTP_ID:

sSQL = "SELECT * FROM Tbl_Primary WHERE RTP_ID = " & lngID 

Однако мне бы хотелось, чтобы RTP_ID мог быть строкой.

Я пробовал:

sSQL = "SELECT * FROM Tbl_Primary WHERE RTP_ID = '" & lngID & "'" 

но до сих пор не работает, какие-либо идеи?

Так что если RTP_ID было 1, это сработало бы, но если было 1A, это не так.

Edit- вот код, который я в настоящее время:

Application.ScreenUpdating = False  

Dim cnn As ADODB.Connection 
Dim rst As ADODB.Recordset 
Dim fld As ADODB.Field 
Dim MyConn 
Dim lngRow As Long 
Dim lngID, LR, Upd 
Dim strID As String 
Dim j As Long 
Dim sSQL As String 

LR = Range("B" & Rows.Count).End(xlUp).Row 
Upd = LR - 1 

lngRow = 2 
Do While lngRow <= LR 


strID = Cells(lngRow, 2).Value 


sSQL = "SELECT * FROM Tbl_Primary WHERE RTP_ID2 = " & strID 



Set cnn = New ADODB.Connection 

MyConn = "Provider = Microsoft.ACE.OLEDB.12.0;" & _ 
"Data Source =\Work\Sites\HLAA\NEW\test\HLAA 2015 NEW.mdb" 
With cnn 

.Provider = "Microsoft.ACE.OLEDB.12.0" 
.Open MyConn 

End With 

Set rst = New ADODB.Recordset 
rst.CursorLocation = adUseServer 
rst.Open sSQL, ActiveConnection:=cnn, _ 
CursorType:=adOpenKeyset, LockType:=adLockOptimistic 

. 

With rst 

.Fields("MonitorCapacity") = Cells(lngRow, 74).Value 


rst.Update 
End With 


rst.Close 
cnn.Close 
Set rst = Nothing 
Set cnn = Nothing 

lngRow = lngRow + 1 

Loop 
MsgBox "You just updated " & Upd & " records" 

Answer 1

Я бы переписать код, как показано ниже:

Dim cnn As Object 
Dim lngRow As Long 
Dim lngID As Long, LR As Long, Upd As Long 
Dim strID As String 

LR = ThisWorkbook.Worksheets("Sheet2").Range("B" & Rows.Count).End(xlUp).Row 
Upd = LR - 1 
lngRow = 2 

Set cnn = CreateObject("ADODB.Connection") 
cnn.Open "Provider=Microsoft.ACE.OLEDB.12.0;" & _ 
    "Data Source=\Work\Sites\HLAA\NEW\test\HLAA 2015 NEW.mdb;" & _ 
    "Persist Security Info=False;" 

Do While lngRow <= LR 
    strID = ThisWorkbook.Worksheets("Sheet2").Cells(lngRow, 2).Value 

    cnn.Execute "UPDATE Tbl_Primary SET MonitorCapacity = '" & _ 
     ThisWorkbook.Worksheets("Sheet2").Cells(lngRow, 74).Value2 & _ 
     "' WHERE RTP_ID2 = '" & strID & "'" 

    lngRow = lngRow + 1 

Loop 
MsgBox "You just updated " & Upd & " records" 

Вы, возможно, потребуется изменить имя рабочего листа - когда вы просто введите Range("B" & Rows.Count), он будет использовать тот, который активен в данный момент, поэтому необходимо указать рабочий лист.