Возможно объединить эти два запроса

Question

У меня есть два запроса cypher и хотелось бы узнать, есть ли возможность получить информацию о точках и HeadHunter в одном заявлении.

MATCH (s:SEASON)-[*]->(e:EVENT)<-[f:FINISHED]-(p:PLAYER) 
    WHERE s.id = 8 AND e.id <= 1197 
    RETURN p, sum(f.points) AS Points 
    ORDER BY Points DESC 

MATCH (s:SEASON)-[*]->(e:EVENT)<-[el:ELIMINATED]-(p:PLAYER) 
    WHERE s.id = 8 AND e.id <= 1197 
    RETURN p, sum(el.points) AS HeadHunter 
    ORDER BY HeadHunter DESC 

Я играл с разными подходами, но никто из них не работал. Я хотел бы сделать что-то вроде этого:

MATCH (s:SEASON)-[*]->(e:EVENT)<-[el:ELIMINATED]-(p:PLAYER),(e)<-[f:FINISHED]-(p) 
    WHERE s.id = 8 AND e.id <= 1197 
    RETURN p, sum(el.points) AS HeadHunter, sum(f.points) AS Points 

Answer 1

Это работает для вас?

MATCH (s:SEASON)-[*]->(e:EVENT)<-[rel:FINISHED|ELIMINATED]-(p:PLAYER) 
WHERE s.id = 8 AND e.id <= 1197 
WITH p, COLLECT(rel) AS rels 
RETURN p, 
    REDUCE(s = 0, x IN rels | CASE WHEN TYPE(x) = 'FINISHED' THEN s + x.points ELSE s END) AS Points, 
    REDUCE(s = 0, x IN rels | CASE WHEN TYPE(x) = 'ELIMINATED' THEN s + x.points ELSE s END) AS HeadHunter 

Это должно возвращать соответствующие суммы для каждого ИГРОКА, которые либо закончены, либо/или устранены.

Answer 2

В принципе, я думаю, что ваш запрос может работать, но вы, возможно, сделали ошибку с p переменной. В этом запросе:

MATCH (s:SEASON)-[*]->(e:EVENT)<-[el:ELIMINATED]-(p:PLAYER),(e)<-[f:FINISHED]-(p) 
    WHERE s.id = 8 AND e.id <= 1197 
    RETURN p, sum(el.points) AS HeadHunter, sum(f.points) AS Points 

Обратите внимание, что p должен быть игроком как с ELIMINATED отношений и в FINISHED отношений. Я предполагаю, что на основе семантики вашего домена это не имеет смысла; вы не можете быть ликвидированы и закончены, правильно?

Таким образом, вы можете попробовать вариант этого:

MATCH (s:SEASON)-[*]->(e:EVENT)<-[el:ELIMINATED]-(pElim:PLAYER),(e)<-[f:FINISHED]-(pFinish) 
    WHERE s.id = 8 AND e.id <= 1197 
    RETURN pElim, sum(el.points) AS HeadHunter, pFinish, sum(f.points) AS Points 

Примечания с этим вы будете иметь много дополнительных строки вывода для различных комбинаций pElim и pFinish, но соответствующие значения должны быть правильными ,