Как проверить, является ли карта подмножеством другого в clojure?

Question

Я хотел бы написать функцию, которая проверяет, является ли карта подмножеством другого.

Пример использования должно быть:

(map-subset? {:a 1 :b 2} {:a 1 :b 2 :c 3}) 
=> true 

Есть ли собственный способ сделать это?

Answer 1

сделать предположение о том, что вы имеете в виду подмножество (прямой перевод этого определения):

(and (every? (set (keys m1)) (keys m2)) ;; subset on keys 
    (every? #(= (m1 %)(m2 %)) (keys m2))) ;; on that subset all the same values 

Answer 2

Существует множество возможных путей решения вашего вопроса. Одним из возможных возможных решений могло бы стать:

(defn contains-submap? [map-structure keys] 
    (every? (partial contains? map-structure) keys)) 

(contains-submap? {:a 1 :b 2 :c 3} (keys {:a 1 :b 2})) 
true 

Это может быть сделано с помощью наборов, например. Но, как указал @kasterma, это зависит от вашего первоначального намерения.

Answer 3

(defn submap? 
    "Checks whether m contains all entries in sub." 
    [^java.util.Map m ^java.util.Map sub] 
    (.containsAll (.entrySet m) (.entrySet sub))) 

REPL демо:

(submap? {:foo 1 :bar 2 :quux 3} {:foo 1 :bar 2}) 
;= true 
(submap? {:foo 1 :bar 2 :quux 3} {:foo 1 :bar 3}) 
;= false 
(submap? {:foo 1 :bar 2} {:foo 1 :bar 2 :quux 3}) 
;= false 

Answer 4

Путем преобразования карты в наборы, вы можете использование clojure.set/subset?

(clojure.set/subset? (set {:a 1 :b 2}) (set {:a 1 :b 2 :c 3})) 
=> true 

Это сделает каждую пару карты элемент в наборе

(set {:a 1 :b 2 :c 3}) 
=> #{[:b 2] [:c 3] [:a 1]} 

И как таковые, {:a 1 :b 3} не будет подмножеством

(clojure.set/subset? (set {:a 1 :b 3}) (set {:a 1 :b 2 :c 3})) 
=> false 

Answer 5

Другим вариантом может быть:

(defn submap? [a b] 
    (= a (select-keys b (keys a)))) 

Это проверяет справедливость ключей на первой карте.

Answer 6

Предполагая, что вы собираетесь ключи и значения соответствуют ...

Есть ли собственный способ сделать это?

Нет стандартной функции. Я предлагаю ...

(defn map-subset? [a-map b-map] 
    (every? (fn [[k _ :as entry]] (= entry (find b-map k))) a-map)) 

Несколько примеров:

(map-subset? {:a 1 :b 2} {:a 1 :b 2 :c 3}) 
=> true 

(map-subset? {:d 4} {:a 1 :b 2 :c 3}) 
=> false 

(map-subset? {:a 3} {:a 1 :b 2 :c 3}) 
=> false 

(map-subset? {:a nil} {}) 
=> false 

• Он проходит свой первый аргумент только один раз.
• Он правильно обрабатывает значения nil.

Если ни одно из них не важно, используйте более элегантную версию, например, kasterma's.