Как сделать универсальную кнопку паузы во Flash CS5?

Question

Я пытаюсь сделать кнопку во Flash, которая приостанавливает все клипы, которые работают в моем файле. Ни один из этих видеороликов не является подростком на моей основной временной шкале, у всех есть своя индивидуальная шкала времени. Каждый клик перемещения запускается кнопкой, которая сообщает клипам начать воспроизведение. Поэтому, если бы кто-нибудь мог помочь мне создать эту кнопку паузы, я был бы очень признателен. Спасибо за ваше время.

Answer 1

Следующая следует сделать трюк:

// create an array to store all playing movieclips 
var playing = []; 

// when a movieclip is played add it to the array like this: 
// playing.push(myMovieClip); 

// call this from your pause button's click handler 
function pauseAll() 
{ 
    // loop through all the playing movieclips ... 
    for (var i = 0; i < playing.length; i ++) 
    { 
     // ... and stop them 
     playing[i].stop(); 
    } 

    // now clear the array 
    playing = []; 
} 

Answer 2

Существует не встроенный способ, который я знаю, чтобы приостановить все видеоклипы.

Если вы сохранили ссылку на клипы, которые вы хотите приостановить на глобально доступном объекте, вы можете перебирать эти ссылки, вызывающие паузу.

Answer 3

Эта функция остановит все вложенные MovieClips объекта. Просто перейдите на сцену или класс отображения верхнего уровня, чтобы остановить/воспроизвести все. Таким образом, вам не нужно отслеживать добавление вещей в массив, и нет накладных расходов.

function recursiveStop(parentClip:DisplayObjectContainer, useStop:Boolean = true, gotoFrame:Object = null):void { 
    var tmpClip:MovieClip = parentClip as MovieClip; 
    if (tmpClip) { 
     if (useStop) { 
      (gotoFrame != null) ? tmpClip.gotoAndStop(gotoFrame) : tmpClip.stop(); 
     }else { 
      (gotoFrame != null) ? tmpClip.gotoAndPlay(gotoFrame) : tmpClip.play(); 
     } 
    } 

    var i:int = parentClip.numChildren; 
    while(i--){ 
     if(parentClip.getChildAt(i) is DisplayObjectContainer){ 
      recursiveStop(parentClip.getChildAt(i) as DisplayObjectContainer, useStop, gotoFrame); 
     } 
    } 
} 

Answer 4

Экспорта ваших все символы, которые вы хотите быть приостановлены/возобновлен рекурсивно с базовым классом, как эта, то вам не придется ходить по всему дереву дисплея:

package com.stackoverflow 
{ 
import flash.display.MovieClip; 
import flash.events.Event; 

[Event(name="clipAdded", type="flash.events.Event")] 
[Event(name="clipRemoved", type="flash.events.Event")] 
public class BaseClip extends MovieClip 
{ 
    protected var baseClipChildren:Array; 
    protected var paused:Boolean = true; 

    public function BaseClip() 
    { 
     super(); 
     baseClipChildren = new Array(); 
     addEventListener(Event.ADDED_TO_STAGE, onAdded); 
     addEventListener("clipAdded", onClipAdded); 
     addEventListener(Event.REMOVED_FROM_STAGE, onRemoved); 
     addEventListener("clipRemoved", onClipRemoved); 
    } 

    protected function onAdded(event:Event):void 
    { 
     var target:BaseClip = event.target as BaseClip; 
     if(target == this) { 
      dispatchEvent(new Event("clipAdded", true)); 
     } 
    } 

    protected function onClipAdded(event:Event):void 
    { 
     var target:BaseClip = event.target as BaseClip; 
     if(target && target != this) { 
      event.stopImmediatePropagation(); 
      baseClipChildren.push(target); 
     } 
    } 

    protected function onRemoved(event:Event):void 
    { 
     var target:BaseClip = event.target as BaseClip; 
     if(target == this) { 
      dispatchEvent(new Event("clipRemoved", true)); 
     } 
    } 

    protected function onClipRemoved(event:Event):void 
    { 
     var target:BaseClip = event.target as BaseClip; 
     if(target && target != this) { 
      event.stopImmediatePropagation(); 
      baseClipChildren.splice(baseClipChildren.indexOf(target),1); 
     } 
    } 

    public function stopAll():void { 
     stop(); 
     for each(var clip:BaseClip in baseClipChildren) { 
      clip.stopAll(); 
     } 
    } 

    public function playAll():void { 
     play(); 
     for each(var clip:BaseClip in baseClipChildren) { 
      clip.playAll(); 
     } 
    } 
} 
}