VBA Excel Double Если

Question

У меня есть различные выпадающие меню в документе и вам нужно создать двойное условное утверждение.

Так что я пытаюсь сделать следующее:

If Cell B14 = Option 1 Then unhide Cells B16:B17 
If Cells B17 = Yes Then hide Cells B19:B53 
If Cells B17 = No Then show Cells B19:B34 

Так что, если кто-то выбирает Option 1 из выпадающего меню, то есть другое выпадающее меню, которые появляются, и если они выбирают Yes от второго по его скрыть требуемые ячейки, и если они выбирают No, он отображает необходимые ячейки.

Опции 2 & 3 в первом выпадающем меню не нужно отображать второй раскрывающийся список.

У меня все работает отдельно от двойного if.

Текущий код:

If Target.Address = "$B$14" Then 

    If Range("B14") = "Option 1: Travel Home" Then 
     ActiveSheet.Rows("16:35").EntireRow.Hidden = False 
     ActiveSheet.Rows("36:55").EntireRow.Hidden = True 
    ElseIf Range("B14") = "Option 2: Travel to next city" Then 
     ActiveSheet.Rows("15").EntireRow.Hidden = False 
     ActiveSheet.Rows("16:17").EntireRow.Hidden = True 
     ActiveSheet.Rows("19:35").EntireRow.Hidden = True 
     ActiveSheet.Rows("36").EntireRow.Hidden = False 
     ActiveSheet.Rows("37:55").EntireRow.Hidden = True 
    ElseIf Range("B14") = "Option 3: Make own arrangements" Then 
     ActiveSheet.Rows("15:36").EntireRow.Hidden = True 
     ActiveSheet.Rows("39:55").EntireRow.Hidden = False 
    End If 

End If 

Вариант 2 и 3 работают нормально только вариант 1 не работает, чтобы отобразить/скрыть, Что необходимо, а также то нужно сделать второй вариант выпадающий которой изменяет то, что является показано на рисунке.

Answer 1

Я проверил приведенный ниже код и, похоже, ведет себя так, как вам хочется. Я сделал некоторые, казалось бы, существенные изменения в структуре, но я сделал это в надежде сделать его более легким для чтения и поддержки в будущем. Я думаю, что мои правки не требуют объяснений.

Я также взял на себя смелость предположить, что это событие Worksheet_Change, даже если вы не использовали состояние экспликации как таковое.

Private Sub Worksheet_Change(ByVal Target As Range) 

Select Case Target.Address 

    Case Is = "$B$14" 

     Select Case Right(Left(Target.Value, 8), 1) 

      Case Is = 1 'Option 1 

       Me.Rows("16:17").EntireRow.Hidden = False 

      Case Is = 2 'Option 2 

       Me.Rows("15").EntireRow.Hidden = False 
       Me.Rows("16:17").EntireRow.Hidden = True 
       Me.Rows("19:35").EntireRow.Hidden = True 
       Me.Rows("36").EntireRow.Hidden = False 
       Me.Rows("37:55").EntireRow.Hidden = True 

      Case Is = 3 'Option 3 

       Me.Rows("15:36").EntireRow.Hidden = True 
       Me.Rows("39:55").EntireRow.Hidden = False 

      Case Else 

       Me.Rows("15:55").EntireRow.Hidden = True 

     End Select 


    Case Is = "$B$17" 

     Me.Range("B19:B35").EntireRow.Hidden = Not (Target.Value = "No") 

End Select 

End Sub 

Вот код, чтобы убедиться, что все строки скрыты при открытии книги.

Private Sub Workbook_Open() 

With Me.Worksheets("SheetName") ' change as needed 
    .Rows("1:3").EntireRow.Hidden = True 
    .Rows("15:55").EntireRow.Hidden = True 
End With 

End Sub