Поднять событие при возврате функции True

Question

Часть программы, которую я модифицирую, включает в себя передачу через последовательный порт с использованием запатентованной библиотеки. К сожалению, эта библиотека не имеет того же SerialPort.DataReceived event, что и пространство имен System.IO.Ports. На самом деле, он не имеет никаких событий вообще, однако у него есть две функции, которые, вероятно, могут быть использованы аналогичным образом:

1. Port.WaitForData (интермедиат время)

   Эта функция ждет определенное количество времени, чтобы получать некоторые ранее указанные строки над портом. Он возвращает 1 для да, полученная строка, или 0 для нет, не получил строку, тайм-аут.

2. Port.IsReceiveBufferEmpty()

   Эта функция возвращает логическое значение из да, приемный буфер пуст или нет, приемный буфер содержит данные.

Мне кажется, я должен создать некоторую нить непрерывно зацикливание при открытии порта и сделать одну из этих двух вещей:

1. Для каждого цикла, называют WaitForData (некоторые большое количество) с указанными строками, которые он ищет для «», или vbCrLf, или что-то еще, что я могу подтвердить, будет получать каждый раз, когда отправляются данные. Если он находит что-то, прочитайте его и напишите в текстовое поле. Если WaitForData ничего не найдет, повторите цикл.

2. Для каждого цикла вызовите IsReceiveBufferEmpty(), а если нет, прочитайте его и напишите в текстовое поле.

Какой лучший способ реализовать это? Первые варианты кажутся потенциально более эффективными для меня, хотя я почти ничего не знаю о том, как этот метод работает под капотом. Очевидно, что я хочу, чтобы моя форма реагировала на это, так как я должен продолжать непрерывный цикл, не замораживая форму, но имея возможность читать любые входящие данные?

Благодарим за помощь.

Answer 1

Возможно, это не самое элегантное решение, но вы можете использовать BackgroundWorker для ввода IO. например что-то вроде этого псевдокода:

Public Class MyForm 

    Private _port As ProprietaryIOLibrary 
    Private WithEvents Worker As System.ComponentModel.BackgroundWorker 

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles Me.Load 
     _port = New ProprietaryIOLibrary() 
     Worker = New System.ComponentModel.BackgroundWorker() 
     Worker.WorkerReportsProgress = True 
     Worker.WorkerSupportsCancellation = True 
     Worker.RunWorkerAsync() 
    End Sub 

    Private Sub ButtonCancel_Click(sender As Object, e As EventArgs) Handles ButtonCancel.Click 
     Worker.CancelAsync() 
    End Sub 

    Private Sub Worker_DoWork(sender As Object, e As DoWorkEventArgs) Handles Worker.DoWork 
     Do 
      If _port.WaitForData(1000) Then ' Adjust timeout depending on cancel responsiveness? 
       Dim data As String = _port.ReadDataAsString() ' ? 
       ' Trigger the ProgressChanged event, passing the data 
       Worker.ReportProgress(0, data) 
      End If 
      If Worker.CancellationPending Then 
       Exit Do 
      End If 
     Loop 
    End Sub 

    Private Sub Worker_ProgressChanged(sender As Object, e As ProgressChangedEventArgs) Handles Worker.ProgressChanged 
     ' Update the UI with the data received 
     ' ProgressChanged is called on the UI thread, so no need to Invoke 
     Dim data As String = DirectCast(e.UserState, String) 
     TextBox1.Text &= data & vbCrLf 
    End Sub 

    Private Sub Worker_RunWorkerCompleted(sender As Object, e As RunWorkerCompletedEventArgs) Handles Worker.RunWorkerCompleted 
     TextBox1.Text &= "Complete!" 
    End Sub 

End Class