Создать задачу Outlook из общего почтового ящика

Question

Мне нужно создать задачу Outlook из общего почтового ящика. До сих пор, когда под кодом работает, задача создается с владельцем общего почтового ящика, как я хочу, но при сохранении я получаю сообщение «Вы должны быть в папке с общедоступной папкой, чтобы изменить имя владельца задачи», и владелец возвращается мне.

Я не мог найти решение, или, возможно, это было за пределами моего понимания. Я ценю помощь. Благодаря!

If task = "YES" Then 
    user_task = "GR" 
    Const olTaskItem = 3 
    Dim OlApp As Object 
    Dim OlTask As Object 

    Set OlApp = CreateObject("Outlook.Application") 
    Set OlTask = OlApp.CreateItem(olTaskItem) 

    With OlTask 
     '.Assign 
     '.Recipients.Add "shared@inbox.com" 'workaround to assign task for another owner, but does not show .BCC so not suitable solution. 
     .Owner = "shared@inbox.com" ' does not work. changes back to my user 
     .Subject = material_full_email & " spp " 
     .StartDate = Date 
     .DueDate = Date + 7 
     .Status = 1     '0=not started, 1=in progress, 2=complete, 3=waiting, 
            '4=deferred 
     .Importance = 1    '0=low, 1=normal, 2=high 
     .ReminderSet = False 
     '.ReminderTime = dtReminderDate 
     '.Categories = "Business" 'use any of the predefined Categorys or create your own 
     .Body = Date & " " & user_task & ":" & " RFQ sent: " & Supplier1 & "/" & Supplier2 & "/" & Supplier3 & "/" & Supplier4 
     '.Save 'use .Display if you wish the user to see the task form and make 
     .Display  'them perform the save 
    End With 
End If 

Answer 1

Вместо использования Application.CreateItem, вызовите Application.Session.CreateRecipient передавая имя или адрес владельца почтового ящика, вызовите Application.Session.GetSharedDefaultFolder, а затем использовать MAPIFolder.Items.Add.

UPDATE:

Set OlApp = CreateObject("Outlook.Application") 
set NS = olApp.getNamespace("MAPI") 
NS.Logon 
ste Recip = NS.CreateRecipient("someuser@company.demo") 
set SharedFolder = NS.GetSharedDefaultFolder(Recip, olFoldersTasks) 
Set OlTask = SharedFolder.Items.Add 
... 

Answer 2

мне удалось получить код ниже работы. Я считаю, что самой большой проблемой была библиотека MS Outlook, не отмеченная в ссылках.

If task = "YES" Then 
    user_task = "GR" 
    Const olTaskItem = 3 
    Dim olApp As Object 
    Dim ns As Object 
    Dim OlTask As Object 
    Dim SharedFolder As Object 
    Set olApp = CreateObject("Outlook.Application") 
    Set ns = olApp.GetNamespace("MAPI") 
    ns.Logon 
    Set Recip = ns.CreateRecipient("inboxname") 
    Set SharedFolder = ns.GetSharedDefaultFolder(Recip, olFolderTasks) 
    Set OlTask = SharedFolder.Items.Add("IPM.Task") 
    'Set OLApp = CreateObject("Outlook.Application") 
    'Set OlTask = OLApp.CreateItem(olTaskItem) 

    With OlTask 
     '.Assign 
     '.Recipients.Add "shared@inbox.com" 
     '.Owner = "shared@inbox.com" ' not needed 
     .Subject = material_full_email & " spp " 
     .StartDate = Date 
     .DueDate = Date + 7 
     .Status = 1     '0=not started, 1=in progress, 2=complete, 3=waiting, 
            '4=deferred 
     .Importance = 1    '0=low, 1=normal, 2=high 
     .ReminderSet = False 
     '.ReminderTime = dtReminderDate 
     '.Categories = "Business" 'use any of the predefined Categorys or create your own 
     .Body = Date & " " & user_task & ":" & " RFQ sent to suppliers: " & Supplier1 & "/" & Supplier2 & "/" & Supplier3 & "/" & Supplier4 
     '.Save 'use .Display if you wish the user to see the task form and make 
     .Display  'them perform the save 
    End With 
End If 

Answer 3

Я думаю, что у меня есть что-то более простое для этого:

Dim objOLApp As Outlook.Application 
Dim NewTask As Outlook.TaskItem 
' Set the Application object 
Set objOLApp = New Outlook.Application 
Set NewTask = objOLApp.Session.Folders.Item(x).Items.Add(olTaskItem) 
With NewTask... 

Где «х» означает для общих Входящих ID (для меня это 5). Вы можете использовать MsgBox Prompt:=objOLApp.Session.Folders.Item(x) для проверки. Он должен вернуть общий адрес входящей почты на правильный идентификатор (adress@server.com).