Проверьте, существует ли каталог или нет

Question

Я пытаюсь проверить, существует ли каталог с использованием Fortan90. На различных сайтах я нашел:

logical :: dir_e 
inquire(file='./docs/.', exist=dir_e) 

if (dir_e) then 
    write(*,*) "dir exists!" 
else 
    ! workaround: it calls an extern program... 
    call system('mkdir docs') 
end if 

Однако inquire возвращает False, существует ли или нет в каталоге, и если я выполняю этот код дважды, я получаю сообщение об ошибке

не может сделать директорию, файл уже существует

Если я использую:

inquire(file='./docs/test', exist=dir_e) 

с существующим файловым тестом, inquire возвращает true.

Как я могу проверить наличие каталога? Я использую ubuntu 11.04 и компилятор ifort.

Answer 1

Следующая должно работать:

INQUIRE (DIRECTORY=dir, EXIST=ex [, DIRSPEC=dirspec] [, ERR=label] [, IOSTAT=i-var]) 

Я не ifort на этой машине, так что я не могу проверить это.

Приложение: Код, который изначально работал с gfortran. Оператор DIRECTORY работает с ifort, но не с gfortran.

И в случае, если для получения дополнительной информации проверки: http://software.intel.com/sites/products/documentation/hpc/compilerpro/en-us/fortran/win/compiler_f/lref_for/source_files/rfinquir.htm#rfinquir

Answer 2

Фортран стандарта 95, 2003 и 2008 не уточняют, как спросить должен относиться к директории. По моему опыту в Linux, gfortran рассматривает их как файлы, ifort - нет. Оператор каталога является запатентованной функцией ifort и поэтому ее следует избегать.

Самым безопасным будет проверка файла в указанном каталоге.

Answer 3

В большинстве случаев проверяется, существует ли каталог, чтобы что-то написать в нем. Я просто создаю каталог. Если он уже существует, проблем нет.

 CALL system("mkdir video") 
    CALL chdir("video") 
    CALL getcwd(path) 

Answer 4

Вот подпрограмма я часто использую - она ​​использует условную вы спросили о:

subroutine create_directory(newDirPath) 
    ! Author: Jess Vriesema 
    ! Date: Spring 2011 
    ! Purpose: Creates a directory at ./newDirPath 

    implicit none 

    character(len=*), intent(in) :: newDirPath 
    character(len=256)   :: mkdirCmd 
    logical      :: dirExists 

    ! Check if the directory exists first 
! inquire(file=trim(newDirPath)//'/.', exist=dirExists) ! Works with gfortran, but not ifort 
    inquire(directory=newDirPath, exist=dirExists)   ! Works with ifort, but not gfortran 


    if (dirExists) then 
!  write (*,*) "Directory already exists: '"//trim(newDirPath)//"'" 
    else 
     mkdirCmd = 'mkdir -p '//trim(newDirPath) 
     write(*,'(a)') "Creating new directory: '"//trim(mkdirCmd)//"'" 
     call system(mkdirCmd) 
    endif 
end subroutine create_directory 

В зависимости от того, какого компилятора вы используете, вы должны решить, какой из этих условных подходят вы.

К сожалению, у меня нет доступа к nagfor и вы не знаете, как он относится к каталогам.

Answer 5

У меня была та же проблема. Если вы хотите, чтобы независимый способ компилятора сделал это, вы можете попробовать открыть небольшой файл в каталоге. Открытое заявление позволяет код для перехода к конкретной строке (указанный ERR =), если открытое заявление терпит неудачу:

! Tests whether the directory exists 
subroutine checkdir(dir) 
     implicit none 
     character(len=*), intent(in) :: dir 
     integer :: unitno 

     ! Test whether the directory exists 
     open(newunit=unitno,file=trim(dir)//'deleteme.txt',status='replace',err=1234) 
     close (unitno) 
     return 

     ! If doesn't exist, end gracefully 
1234 write(*,*) 'Data directory, '//trim(dir)//' does not exist or could not write there!' 
     STOP 

end subroutine 

Обратите внимание, что это не является надежным, так как предполагается, «реж» имеет завершающую "/"или" \ "в зависимости от используемой ОС.

Answer 6

Другого непереносимым решения позволить оболочки (Bash, в данном случае) сделать работу:

call system('[[ ! -e docs ]] && mkdir docs') 

Answer 7

Вы можете использовать процедуры C, чтобы проверить файлы:

C стороны (OK с ifort и gfortran на Win32 и Linux 32/64)

#include <stdlib.h> 
#include <stdio.h> 
#include <string.h> 
#include <errno.h> 
#include <sys/stat.h> 
#if defined(_WIN32) && defined(__INTEL_COMPILER) 
# include "dirent_windows.h" 
#else 
# include <dirent.h> 
#endif 

void file_info(const char*filename,int*mode,int*exist,int*time){ 
    int k; 
    struct stat buf; 
    k=stat(filename,&buf); 
    if(k != 0) { 
    *mode=0; 
    *exist=0; 
    *time=0; 
    }else{ 
    *mode=buf.st_mode; 
    if(*mode == 0) *exist=0; else *exist=1; 
    *time=buf.st_mtime; 
    } 
} 

Fortran стороне:

MODULE file 

    USE iso_c_binding 

    INTERFACE 
    SUBROUTINE file_info(filename,mode,exist,time) BIND(C,name="file_info") 
     USE iso_c_binding 
     CHARACTER(kind=C_CHAR),INTENT(in) :: filename(*) 
     INTEGER(C_INT),INTENT(out) :: mode,exist,time 
    END SUBROUTINE 
    END INTERFACE 

END MODULE 

Как использовать в Fortran рутина:

.. 
use file 
use iso_c_binding 
... 
integer(c_int) :: mode,exist,time 
... 
call file_info("./docs"//char(0),mode,exist,time) 

преимущество: она работает для любого типа файла и предоставляет дополнительные элементы информации, как и в режиме (чтение/запись/разрешение на выполнение) и время создания.