Maple Plot functions

Question

Кто-нибудь знает, как построить функцию Дирака в левом верхнем углу и функцию синуса, указанную на картинке. Мне удалось построить второй и третий легко. Не могли бы вы сделать это с кусочной функцией или есть простой способ для Plot # 1 и # 4? Большое спасибо!

Arbitrary Excitations

Answer 1

Если это домашнее задание, то я полагаю, что для примера синусового вас просят, чтобы исследовать эффекты масштаба и сдвига.

Рассмотрите эти участки, один за другим. Наблюдайте, как они отличаются. Сначала я масштабирую величину (у-направление) на 10. Затем я масштабируюсь по оси х. И, наконец, я перехожу в направлении x.

plots:-setoptions(size=[300,0.6],tickmarks=[decimalticks,default]): 
plot(10*sin(x), x=0 .. Pi, view=[0..Pi, 0..18]); 

plot(10*sin(x*Pi), x=0 .. 1, view=[0..1, 0..18]); 

plot(10*sin(x*Pi/0.3), x=0 .. 0.3, view=[0..1, 0..18]); 

plot(10*sin((x-0.1)*Pi/0.3), x=0.1 .. 0.4, view=[0..1, 0..18]); 

plots:-setoptions(); 

Это может быть похоже на 4-й участок изображения, с которым вы легко связаны. Вы можете попробовать его с помощью различных вариантов.

P:= plot(10*sin((x-0.1)*Pi/0.3), x=0.1 .. 0.4 
      , axes=none 
      , color=black 
      , size=[300,0.7] 
      , thickness=2 
     ): 

plots:-display(P 
       , view=[0.0 .. 0.6, 0..18] 
       , tickmarks=[[0.1,0.4],[10=10*N]] 
       , axes=normal, labels=[`t[s]`,`F(t)`] 
       , size=[300,0.6] 
      ); 

И с большим усилием он может быть более точное соответствие, визуально.

plots:-display(P 
      , plottools:-arrow([0,0],[0.6,0], 0.05, 0.9, 0.05) 
      , plottools:-arrow([0,0],[0,16], 0.001, 0.02, 0.08) 
      , plots:-textplot([0.6, -3.5, `t[s]`, font=["courier",16]]) 
      , plots:-textplot([0.0, 18, `F(t)`, font=["courier",16]]) 
      , seq(plots:-textplot([X, -1.5, X]), X=[0,0.1,0.4]) 
      , plots:-textplot([-0.05, 10, "10 N"]) 
      ); 

Для вашего другого участка можно просто построить последовательность строк.

T:=table([1=60,2=100,3=0,4=20]): 
P2:=seq(plottools:-line([i,0],[i,T[i]],thickness=2,color=black), 
     i=1..4): 

И вы можете настроить внешний вид заключительного участка, как указано выше. Я оставлю это вам.

plots:-display(P2 
       , size=[300,0.7] 
       , view=[0..6, 0..120] 
       , labels=["",""] 
      );