Обертка для члена типа

Question

Я пытаюсь реализовать универсальную функцию, которая вызывает член типа. Я обнаружил, что это должно быть возможно, используя inline. Это не помогло, поэтому я попытался реализовать интерфейс, например:

type Wrappable<'a, 'b> = 
    interface 
     abstract Wrap : ('b -> 'b) -> 'a 
    end 

type StateType = 
    State of Scene * Cash | Exit 
    interface Wrappable<StateType, Scene * Cash> with 
     member this.Wrap f = 
      match this with 
      | Exit -> Exit 
      | State (scene, cash) -> f (scene, cash) |> State 

let inline wrap f (o:Wrappable<_, _>) = o.Wrap f 

Это работает очень хорошо, давая выход типа

type Wrappable<'a,'b> = 
    interface 
    abstract member Wrap : ('b -> 'b) -> 'a 
    end 
type StateType = 
    | State of Scene * Cash 
    | Exit 
    with 
    interface Wrappable<StateType,(Scene * Cash)> 
    end 
val inline wrap : f:('a -> 'a) -> o:Wrappable<'b,'a> -> 'b 

я нахожу этот способ быть очень некрасиво, хотя , Мой вопрос: есть ли лучший способ обернуть член в функцию?

Answer 1

это, как вы можете сделать это с помощью statically resolved type parameters я упомянул:

type StateType = 
    State of int * string | Exit 
     member this.Wrap f = 
      match this with 
      | Exit -> Exit 
      | State (scene, cash) -> f (scene, cash) |> State 

let inline wrap f (o : ^a) = (^a : (member Wrap : (^b -> ^b) -> ^a) (o, f)) 

Я использовал int * string, потому что я не знаю вашего Scene и Cash и хотите проверить:

> let x = State (5,"Hallo");; 

val x : StateType = State (5,"Hallo") 

> let f (x,y) = (x+x,y);; 

val f : x:int * y:'a -> int * 'a 

> wrap f x;; 

val it : StateType = State (10,"Hallo") 

Answer 2

Почему бы не использовать оператора? неявно разрешенный символический оператор будет скомпилирован как статическое выражение вызова ограничения числа в любом случае без уродливого синтаксиса. Эта языковая функция зависит от статически разрешенных параметров типа. См. 14.2.2 (последняя строка) F# spec.

type StateType = 
    State of int * string | Exit 
    static member ($) (this, f) = 
     match this with 
     | Exit -> Exit 
     | State (scene, cash) -> f (scene, cash) |> State 

type UnitType = 
    | Etats of float * unit 
    static member ($) (Etats (scene,()), f) = 
     f (scene,()) |> Etats 

let inline f (x,y) = (x+x,y) 

let st = State (5,"Hallo") 
st $ f // val it : StateType = State (10,"Hallo") 

let ut = Etats (5.,()) 
ut $ f // val it : UnitType = Etats (10.0,null)