Запретить пользователям вводить дату

Question

У меня есть диапазон ячеек, которые должны быть в формате учета. Проблема заключается в том, что когда пользователи пытаются ввести дату, она меняет формат ячейки на сегодняшний день и перепутает вычисления. Я хочу, чтобы ошибка окна сообщения всплывала и очищала недопустимые данные, когда пользователь пытается ввести дату.

У меня уже есть проверка данных, установленная до десятичной, но когда я пытаюсь проверить ее, введя дату (1/2, 1/2/11 или 1-2-11), excel изменяет формат номера ячейки на дроби или дата и событие ошибки проверки не происходит.

В качестве альтернативы, есть ли способ от меня заблокировать формат чисел для диапазона ячеек, чтобы excel прекратил преобразовывать формат ячейки на основе пользовательского ввода?

Answer 1

Вы можете поместить этот код в Модуль VBA для рабочего листа. Он показывает сообщение, очищает значение и устанавливает формат обратно в Учет и отчетность:

Private Sub Worksheet_Change(ByVal Target As Range) 
Dim AccountingRange As Excel.Range 
Dim cell As Excel.Range 

Set AccountingRange = Me.Range("B2:B20") 
If Intersect(Target, AccountingRange) Is Nothing Then 
    Exit Sub 
End If 

Application.EnableEvents = False 
For Each cell In Intersect(Target, AccountingRange) 
    If IsDate(cell.Text) Then 
     With cell 
      MsgBox "You entered a date in " & .Address & "." & vbCrLf & "Please don't do that!" 
      cell.ClearContents 
      .NumberFormat = "_($* #,##0.00_);_($* (#,##0.00);_($* ""-""??_);_(@_)" 
     End With 
    End If 
Next cell 
Application.EnableEvents = True 
End Sub 

Answer 2

Вы можете использовать инструмент проверки данных в Excel

С помощью этого вы можете заставить пользователя ввести определенный тип данных в ячейке