Таймер AI не работает

Question

 var moveTimer:Timer = new Timer(1); 
     moveTimer.addEventListener(TimerEvent.TIMER, timerListener); 
     function timerListener (e:TimerEvent):void 
     { 
      //code 
     } 
     moveTimer.start(); 
     moveTimer.addEventListener(TimerEvent.TIMER_COMPLETE, timerDone) 
     function timerDone(e:TimerEvent):void 
     { 
      upKey = false; 
     } 

Привет, ребята, так что это мой код. У меня есть очень упрощенный AI в моей игре, и я пытаюсь использовать таймер, чтобы противник двигался вперед примерно на 2-3 секунды, а затем останавливался. Для этого я использую переменную upKey как boolean, для которой установлено значение true, но когда таймер заканчивается, он получает значение false, а при установке false, есть оператор if, который уменьшает скорость противника до 0 .

Это мой первый таймер, и враги не останавливаются ... они вроде как продолжат идти, пока они не уйдут с экрана. Я делаю это правильно или это проблема в другом месте моего кода? Кроме того, есть ли более эффективный способ использования таймера?

Спасибо, Джеймс.

Answer 1

Из кода, который вы цитируете, конструктор таймера не указывает repeatCount, указывающий, что он должен повторяться неопределенно долго. Для обработчика timerDone() вы должны указать количество повторов.

Также обратите внимание, что задержка менее 20 миллисекунд не рекомендуется.

параметры таймера конструктора: Timer(delay:Number, repeatCount:int = 0)

delay:Number - Задержка между событиями таймера в миллисекундах. A Задержка менее 20 миллисекунд не рекомендуется. Частота таймера ограничена 60 кадрами в секунду, что означает задержку ниже 16,6 миллисекунд, что приводит к проблемам времени выполнения.

repeatCount:int (default = 0) - Указывает количество повторений. Если нуль, таймер повторяется неограниченно, до 24.86 дней (int.MAX_VALUE + 1). Если отличное от нуля, таймер запускает заданное число раз, а затем останавливается.

Таймеры не рекомендуются для анимированного контента. Вместо этого используйте Event.ENTER_FRAME для управления анимацией на основе кадра.

Один подход должен был бы использовать таймеры, чтобы вызвать изменения состояния вашей модели игры:

/** timer */ 
var timer:Timer; 

/** whether enemies are advancing */ 
var advance:Boolean = false; 

// start timer at 5-seconds intervals 
timer = new Timer(5000); 
timer.addEventListener(TimerEvent.TIMER, timerHandler); 
timer.start(); 

// animation controlled by Event.ENTER_FRAME 
addEventListener(Event.ENTER_FRAME, frameHandler); 

В обработчике таймера, вы можете настроить задержку таймера в зависимости от состояния вашей игры.

/** timer handler */ 
function timerHandler(event:TimerEvent):void 
{ 
    // stop the current timer 
    timer.stop(); 

    // depending on the current enemy state 
    switch (advance) 
    { 
     // if true, stop advancing and wait 5-seconds 
     case true: 
      trace("Stop advancing, wait 5-seconds"); 
      timer.delay = 5000; 
      break; 
     // if false, advance for 2-seconds 
     case false: 
      trace("Advance for next 2-seconds"); 
      timer.delay = 2000; 
      break; 
    } 

    // invert advance state. 
    advance = !advance; 

    // restart timer 
    timer.start(); 
} 

Аналогично на введите кадр, управление анимацией вашего противника на основе состояния игры:

/** frame handler, advancing enemy if 'advance' is true */ 
function frameHandler(event:Event):void 
{ 
    if (advance) { /** move enemy forward */ } 
} 

Это чередуется состояние ваших врагов, выводя:

Advance для следующих 2-х секунд
Остановить движение, подождать 5 секунд
Прогресс на следующие 2 секунды
Остановить движение, подождать 5 секунд
Прогресс на следующие 2 секунды