Сглаживание XML с использованием XSLT, но на основе уровня вложенности

Question

Я новичок в XSLT, и я пытаюсь написать некоторый XSLT, который сгладит любой данный XML, так что новая строка возникает всякий раз, когда изменяется уровень вложенности. Моим входом может быть любой XML-документ с любым количеством вложенных уровней, чтобы структура не была известна XSLT. Благодаря имеющимся у меня инструментам, мое решение должно использовать XSLT версии 1.0.

Например.

<?xml version="1.0"?> 
<ROWSET> 
    <ROW> 
    <CUSTOMER_ID>0</CUSTOMER_ID> 
    <NAME>Default Company</NAME> 
    <BONUSES> 
     <BONUSES_ROW> 
     <BONUS_ID>21</BONUS_ID> 
     <DESCRIPTION>Performance Bonus</DESCRIPTION> 
     </BONUSES_ROW> 
     <BONUSES_ROW> 
     <BONUS_ID>26</BONUS_ID> 
     <DESCRIPTION>Special Bonus</DESCRIPTION> 
     </BONUSES_ROW> 
    </BONUSES> 
    </ROW> 
    <ROW> 
    <CUSTOMER_ID>1</CUSTOMER_ID> 
    <NAME>Dealer 1</NAME> 
    <BONUSES> 
     <BONUSES_ROW> 
     <BONUS_ID>27</BONUS_ID> 
     <DESCRIPTION>June Bonus</DESCRIPTION> 
     <BONUS_VALUES> 
      <BONUS_VALUES_ROW> 
      <VALUE>10</VALUE> 
      <PERCENT>N</PERCENT> 
      </BONUS_VALUES_ROW> 
      <BONUS_VALUES_ROW> 
      <VALUE>11</VALUE> 
      <PERCENT>Y</PERCENT> 
      </BONUS_VALUES_ROW> 
     </BONUS_VALUES> 
     </BONUSES_ROW> 
    </BONUSES> 
    </ROW> 
</ROWSET> 

потребности в становится ....

0, Default Company 
21, Performance Bonus 
26, Special Bonus 
1, Dealer 1 
27, June Bonus 
10, N 
11, Y 

XSLT я написал до сих пор есть ...

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="text" encoding="iso-8859-1"/> 
    <xsl:strip-space elements="*" /> 
    <xsl:template match="/*/child::*"> 
    <xsl:apply-templates select="*"/> 
    </xsl:template> 
    <xsl:template match="*"> 
    <xsl:value-of select="text()" /> 
    <xsl:if test="position()!= last()"><xsl:text>,</xsl:text></xsl:if> 
    <xsl:if test="position()= last()"><xsl:text>&#xD;</xsl:text></xsl:if>  
    <xsl:apply-templates select="./child::*"/>   
    </xsl:template> 
</xsl:stylesheet> 

, но мой выход только не правильно, с пробелов и ненужных данных.

0,Default Company, 
,21,Performance Bonus 

26,Special Bonus 
1,Dealer 1, 

27,June Bonus, 
,10,N 

11,Y 

Кажется, там должно быть чеком, как, может ли узел содержать текст, но я застрял и мог сделать с помощью XSLT не давал эксперт.

Answer 1

Вы можете проверить, чтобы увидеть, если элемент имеет текст, выполнив: *[text()]

Пример ...

XML Input

<ROWSET> 
    <ROW> 
     <CUSTOMER_ID>0</CUSTOMER_ID> 
     <NAME>Default Company</NAME> 
     <BONUSES> 
      <BONUSES_ROW> 
       <BONUS_ID>21</BONUS_ID> 
       <DESCRIPTION>Performance Bonus</DESCRIPTION> 
      </BONUSES_ROW> 
      <BONUSES_ROW> 
       <BONUS_ID>26</BONUS_ID> 
       <DESCRIPTION>Special Bonus</DESCRIPTION> 
      </BONUSES_ROW> 
     </BONUSES> 
    </ROW> 
    <ROW> 
     <CUSTOMER_ID>1</CUSTOMER_ID> 
     <NAME>Dealer 1</NAME> 
     <BONUSES> 
      <BONUSES_ROW> 
       <BONUS_ID>27</BONUS_ID> 
       <DESCRIPTION>June Bonus</DESCRIPTION> 
       <BONUS_VALUES> 
        <BONUS_VALUES_ROW> 
         <VALUE>10</VALUE> 
         <PERCENT>N</PERCENT> 
        </BONUS_VALUES_ROW> 
        <BONUS_VALUES_ROW> 
         <VALUE>11</VALUE> 
         <PERCENT>Y</PERCENT> 
        </BONUS_VALUES_ROW> 
       </BONUS_VALUES> 
      </BONUSES_ROW> 
     </BONUSES> 
    </ROW> 
</ROWSET> 

XSLT 1,0

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="text"/> 
    <xsl:strip-space elements="*"/> 

    <xsl:template match="*[text()]"> 
     <xsl:if test="position() > 1"> 
      <xsl:text>, </xsl:text> 
     </xsl:if> 
     <xsl:value-of select="."/> 
     <xsl:if test="not(following-sibling::*[text()])"> 
      <xsl:text>&#xA;</xsl:text>   
     </xsl:if> 
    </xsl:template> 

</xsl:stylesheet> 

Текст Выходной

0, Default Company 
21, Performance Bonus 
26, Special Bonus 
1, Dealer 1 
27, June Bonus 
10, N 
11, Y 

Кроме того, посмотрите на Built-in Template Rules, чтобы увидеть, что делает эту таблицу стилей работы только с одним шаблоном.

EDIT

Эта таблица стилей также выдает запятая для пустых элементов:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="text"/> 
    <xsl:strip-space elements="*"/> 

    <xsl:template match="*[text() or not(*)]"> 
     <xsl:if test="position() > 1"> 
      <xsl:text>, </xsl:text> 
     </xsl:if> 
     <xsl:value-of select="."/> 
     <xsl:if test="not(following-sibling::*[text() or not(*)])"> 
      <xsl:text>&#xA;</xsl:text>   
     </xsl:if> 
    </xsl:template> 

</xsl:stylesheet> 

Answer 2

Проверка или подтвердить свой XML.

In your XML, Start Node <ROWSET> does not end with </ROWSET> 

If <ROWSET> node ends with </ROWSET> then, following XSL code will work for your expectation output 

<xsl:template match="ROWSET"> 
    <xsl:for-each select="ROW"> 
     <xsl:value-of select="CUSTOMER_ID"/>, <xsl:value-of select="NAME"/><xsl:text>&#10;</xsl:text> 

     <xsl:for-each select="BONUSES/BONUSES_ROW"> 
      <xsl:value-of select="BONUS_ID"/>, <xsl:value-of select="DESCRIPTION"/><xsl:text>&#10;</xsl:text> 
      <xsl:variable name="cnt" select="count(BONUS_VALUES/BONUS_VALUES_ROW)"/> 
      <xsl:if test="$cnt &gt; 0"> 
       <xsl:for-each select="BONUS_VALUES/BONUS_VALUES_ROW"> 
        <xsl:value-of select="VALUE"/>, <xsl:value-of select="PERCENT"/><xsl:text>&#10;</xsl:text> 
       </xsl:for-each> 
      </xsl:if> 
     </xsl:for-each> 
    </xsl:for-each> 
</xsl:template>