Outlook VBA, поврежденный считываемыми квитанциями

Question

У меня есть этот код, который работает с входящими сообщениями. Затем он удаляет вложение, а затем отправляет электронное письмо на другой адрес. Это прерывается чтением квитанций, потому что я предполагаю, что они не считаются MailItem.

Private Sub Application_NewMailEx(ByVal EntryIDCollection As String) 
Dim varEntryID As Variant 

For Each varEntryID In Split(EntryIDCollection, ",") 
    Dim objOriginalItem As MailItem 
    Set objOriginalItem = Application.GetNamespace("MAPI").GetItemFromID(varEntryID) 
    Dim objForwardedItem As MailItem 
    Set objForwardedItem = objOriginalItem.Forward 

    Do Until objForwardedItem.Attachments.Count = 0 
     objForwardedItem.Attachments.Remove (1) 
    Loop 

    objForwardedItem.DeleteAfterSubmit = True 
    objForwardedItem.To = "LoanPostClosing@domain.com" 
    objForwardedItem.Send 
Next 
End Sub 

Answer 1

Вам необходимо обработать новый элемент как общий объект и проверить свойство класса. Смотри ниже.

Private Sub Application_NewMailEx(ByVal EntryIDCollection As String) 
Dim varEntryID As Variant 

For Each varEntryID In Split(EntryIDCollection, ",") 
    Dim objOriginalItem As Object 
    Set objOriginalItem = Application.GetNamespace("MAPI").GetItemFromID(varEntryID) 
    if objOriginalItem.Class = 43 Then 
     Dim objForwardedItem As MailItem 
     Set objForwardedItem = objOriginalItem.Forward 

     Do Until objForwardedItem.Attachments.Count = 0 
      objForwardedItem.Attachments.Remove (1) 
     Loop 

     objForwardedItem.DeleteAfterSubmit = True 
     objForwardedItem.To = "LoanPostClosing@yourcnb.com" 
     objForwardedItem.Send 
    End If 
Next 
End Sub