XSLT Transform с исходным вложенным уровнем

Question

Я отредактировал проблему, чтобы прояснить ситуацию. Я хочу, чтобы извлечь все сечения узлов с их раздела узлов и заголовка узла включены, сохраняя вложенные level.Below является выходным результатом я хотел:

<?xml version="1.0" encoding="UTF-8"?> 
<results> 
    <section id="intro" difficulty="easy"> 
     <title>Introduction</title> 
     <section> 
      <title>Web Data and the Two Cultures</title> 
     </section> 
    </section> 
    <section id="syntax" difficulty="medium"> 
     <title>A Syntax For Data</title> 
     <section> 
      <title>Base Types</title> 
     </section> 
     <section> 
      <title>Representing Relational Databases</title> 
     </section> 
     <section> 
      <title>Representing Object Databases</title> 
     </section> 
    </section> 
</results> 

И содержание XML, как это:

<?xml version="1.0" encoding="UTF-8"?> 
<?xml-stylesheet type="text/xsl" href="book.xsl"?> 
<book> 
    <title>Data on the Web</title> 
    <author>Serge Abiteboul</author> 
    <author>Peter Buneman</author> 
    <author>Dan Suciu</author> 
    <section id="intro" difficulty="easy"> 
     <title>Introduction</title> 
     <p>Text ... </p> 
     <section> 
      <title>Web Data and the Two Cultures</title> 
      <p>Text ... </p> 
      <figure height="400" width="400"> 
       <title>Traditional client/server architecture</title> 
       <image source="csarch.gif"/> 
      </figure> 
      <p>Text ... </p> 
     </section> 
    </section> 
    <section id="syntax" difficulty="medium"> 
     <title>A Syntax For Data</title> 
     <p>Text ... </p> 
     <figure height="200" width="500"> 
      <title>Graph representations of structures</title> 
      <image source="graphs.gif"/> 
     </figure> 
     <p>Text ... </p> 
     <section> 
      <title>Base Types</title> 
      <p>Text ... </p> 
     </section> 
     <section> 
      <title>Representing Relational Databases</title> 
      <p>Text ... </p> 
      <figure height="250" width="400"> 
       <title>Examples of Relations</title> 
       <image source="relations.gif"/> 
      </figure> 
     </section> 
     <section> 
      <title>Representing Object Databases</title> 
      <p>Text ... </p> 
     </section> 
    </section> 
</book> 

Вот мое решение, которое является неправильным:

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 
<xsl:template match="/book"> 
    <xsl:apply-templates select="section"/> 
</xsl:template> 
<xsl:template match="section"> 
    <xsl:element name="section"> 
     <xsl:for-each select="@*"> 
      <xsl:attribute name="{name()}"><xsl:value-of select="."/></xsl:attribute> 
     </xsl:for-each> 
    </xsl:element> 
    <xsl:apply-templates select="title"/> 
    <xsl:apply-templates select="section"/> 
</xsl:template> 
<xsl:template match="title"> 
    <xsl:element name="title"> 
     <xsl:for-each select="@*"> 
      <xsl:attribute name="{name()}"><xsl:value-of select="."/></xsl:attribute> 
     </xsl:for-each> 
     <xsl:value-of select="."/> 
    </xsl:element> 
</xsl:template> 
</xsl:stylesheet> 

Я думал об использовании рекурсии, но я не нашел, как это сделать в XSLT. Должны быть другие способы. Спасибо заранее!

Answer 1

Если все, что вы на самом деле пытаетесь сделать, это переименовать book элемент results вам нужно начать с XSLT identity template

<xsl:template match="@*|node()"> 
    <xsl:copy> 
    <xsl:apply-templates select="@*|node()"/> 
    </xsl:copy> 
</xsl:template> 

О себе, он копирует все узлы из исходного документа, как есть, что вам нужно только написать шаблон для узлов, которые вы хотите изменить. В этом случае, вы изменяете book элемент, так что вы бы конкретный шаблон для этого, например, так:

<xsl:template match="book"> 
    <results> 
    <xsl:apply-templates select="@*|node()"/> 
    </results> 
</xsl:template> 

Кроме того, если вы хотите, чтобы удалить элементы, кроме section и title (и book), один путь должен иметь шаблон, соответствующий «другим» элементам, и просто игнорировать их

<xsl:template match="*[not(self::book) and not(self::section) and not(self::title)]" /> 

И все! Попробуйте XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml" indent="yes" /> 

    <xsl:template match="book"> 
    <results> 
     <xsl:apply-templates select="@*|node()"/> 
    </results> 
    </xsl:template> 

    <xsl:template match="*[not(self::book) and not(self::section) and not(self::title)]" /> 

    <xsl:template match="@*|node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
    </xsl:copy> 
    </xsl:template> 
</xsl:stylesheet> 

Имейте в виду, хотя, если вы используете <?xml-stylesheet сделать преобразование на стороне клиента, браузер может только показывать только текст, а не XML, потому что он действительно ожидает, что выход будет HTML. Вы можете увидеть фактические результаты, выполнив View (Page) Source.