Идиоматический способ «обновления» заданного ключа на карте Clojure?

Question

Скажем, у нас есть карта, которая выглядит примерно так:

(def m {:a {:foo "bar"}}) 

Теперь мы хотели бы, чтобы обновить ключ: а в м с некоторыми новыми значениями:

(def vs {:baz "qux"}) 

Если бы это было Python мы могли сделать что-то вроде:

>>> d = {'a': {'foo': 'bar'}} 
>>> d['a'].update({'baz': 'qux'}) 
>>> d 
{'a': {'foo': 'bar', 'baz': 'qux'}} 

Самого простого Clojure эквивалента я нашел в том, чтобы определить такую ​​функцию:

(defn update-key 
    " 
    Updates a given key `k` over a map `m` with a map of values `vs`. 
    " 
    [k m vs] 
    (assoc m k (merge (k m) vs))) 

, который затем вызывается как:

(update-key :a m vs) 
; => {:a {:foo "bar" :baz "qux"}} 

Так что мой вопрос: Что такое наиболее идиоматических и правильный путь для достижения той же функциональности, как dicts update() метод Python предоставить?

Answer 1

Я думаю, что вы ищете assoc-in:

(def m {:a {:foo "bar"}}) 

(assoc-in m [:a :foo] "qux") 
; => {:a {:foo "qux"}} 

(assoc-in m [:a :baz] "qux") 
; => {:a {:foo "bar", :baz "qux"}} 

update-in похож, и может быть стоит посмотреть на слишком. Это может быть на самом деле ближе к примеру Python:

(def m {:a {:foo "bar"}}) 
(def vs {:baz "qux"}) 

(update-in m [:a] merge vs) 
; => {:a {:foo "bar", :baz "qux"}} 

---

Update:

Даже если ключ является переменной величиной (не компиляции постоянного времени) вы можете использовать как update-in и assoc-in, помещая переменную в векторе:

(def m {:a {:foo "bar"}}) 
(def k' :baz) 
(def v' "qux") 

(assoc-in m [:a k'] v') 
; => {:a {:foo "bar", :baz "qux"}} 

Вы также можете построить ключи вектор программно:

(def m {:a {:foo "bar"}}) 
(def k' :baz) 
(def v' "qux") 

(let [ks (conj [:a] k')] 
    (assoc-in m ks v')) 
; => {:a {:foo "bar", :baz "qux"}}