Храните товар на одном и том же месте монитора независимо от размера окна/позиции

Question

Я пытаюсь создать игру с полноэкранным.

Когда я добавить объект в stage в полноэкранном режиме, то хотелось бы, чтобы остаться в тех же координатах (например, 1000 пикселей) по отношению к монитора, когда я выйти из полноэкранного режима.

Как я могу заставить объект перемещаться в одно и то же место при выходе из полноэкранного режима?

Answer 1

Чтобы получить ваш начал:

Что-то вдоль этих линий, что вам нужно сделать:

stage.align = StageAlign.TOP_LEFT; //you'll need to running a top-left no-scale swf for this to work 
stage.scaleMode = StageScaleMode.NO_SCALE; 

var itemPoint:Point = new Point(150,150); //the point on the monitor the object should reside 

//call this anytime the item needs to be redrawn (eg when the window changes size or position) 
function updatePos(e:Event = null){ 
    //We need to also account for the chrome of the window 
    var windowMargin:Number = (stage.nativeWindow.bounds.width - stage.stageWidth) * .5; //this is the margin or padding that between the window and the content of the window 
    var windowBarHeight:Number = stage.nativeWindow.bounds.height - stage.stageHeight - windowMargin; //we have to assume equal margin on the left/right/bottom of the window 

    item.x = itemPoint.x - stage.nativeWindow.x - windowMargin; 
    item.y = itemPoint.y - stage.nativeWindow.y - windowBarHeight; 
} 

stage.nativeWindow.addEventListener(NativeWindowBoundsEvent.MOVE, updatePos); //we need to listen for changes in the window position 
stage.nativeWindow.addEventListener(NativeWindowBoundsEvent.RESIZE, updatePos); //and changes in the window size 

//a click listener to test with 
stage.addEventListener(MouseEvent.CLICK, function(e:Event):void { 
    if(stage.displayState == StageDisplayState.FULL_SCREEN_INTERACTIVE){ 
     stage.displayState = StageDisplayState.NORMAL; 
    }else{ 
     stage.displayState = StageDisplayState.FULL_SCREEN_INTERACTIVE; 
    } 
}); 

updatePos();