Запустите банку для конкретных писем в Outlook

Question

Я должен запускать некоторый Java-код каждый раз, когда получаю конкретное письмо. Я просто загружаю вложение в электронном письме, запускаю банку и отвечаю ответом от выполнения этой банки с приложением.

Можно ли как-то автоматизировать это?

Я проверил подпрограммы VBA, которые можно вызывать с помощью правил Outlook, но я не уверен, могу ли я выполнить свой файл jar с этим.

Любые идеи?

Answer 1

Вот эта структура, я позволю вам ее настроить!

Вы можете установить правило для использования SaveToDiskAndReply, который является основной программой.

Paste это в начале вашего модуля Outlook:

Option Explicit 

Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long) 

Private Sub RunSleep(_ 
        exec As WshExec, _ 
        Optional timeSegment As Long = 800 _ 
        ) 
    Do While exec.Status = WshRunning 
     Sleep timeSegment 
    Loop 
End Sub 

Private Function RunProgram(_ 
          program As String, _ 
          Optional command As String = "" _ 
          ) As WshExec 
    Dim wsh As New WshShell 
    Dim exec As WshExec 

    Set exec = wsh.exec(program) 
    Call exec.StdIn.WriteLine(command) 
    Call RunSleep(exec) 
    Set RunProgram = exec 
End Function 

Public Function Run_Jar() As String 
    Dim program As WshExec 
    Dim value As String 
    '''Set the path (jar and log) 
    Set program = RunProgram("java -jar ""D:\\Demo.jar"" 8861ccd621") 
    DoEvents 
    Run_Jar = program.StdOut.ReadAll 
End Function 

и использовать его в качестве сценария запущенного по правилу:

Public Sub SaveToDiskAndReply(ItM As Outlook.MailItem) 
    Dim oAttS As Outlook.Attachments 
    Dim objAtt As Outlook.Attachment 
    Dim oItM As Outlook.MailItem 
    Dim saveFolder As String 
    Dim dateFormat As String 
    Dim JarReturn As String 

    dateFormat = Format(Now, "yyyy-mm-dd") 
    saveFolder = "c:\temp\" 
    Set oAttS = ItM.Attachments 

    '''Save the attachements 
    For Each objAtt In oAttS 
     objAtt.SaveAsFile saveFolder & objAtt.FileName 
    Next objAtt 

    '''Run your jar 
    JarReturn = Run_Jar 

    '''Fill the email 
    Set oItM = OutApp.CreateItem(0) 


    '''Decomment the next line when you're done testing 
    'On Error Resume Next 
    With oItM 
     .To = ItM.SenderEmailAddress 
     .CC = "" 
     .BCC = "" 
     .Subject = ItM.Subject 
     .Body = JarReturn 
     For Each objAtt In oAttS 
      .Attachments.Add saveFolder & objAtt.FileName 
     Next objAtt 
     .Send 'or use .Display 
    End With 
    On Error GoTo 0 

    Set oAttS = Nothing 
    Set objAtt = Nothing 
End Sub